Program g01ha_a1w_fe

!     G01HA_A1W_F Example Program Text
!     Mark 30.2 Release. NAG Copyright 2024.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: g01ha_a1w_f, nagad_a1w_get_derivative,          &
                               nagad_a1w_inc_derivative,                       &
                               nagad_a1w_ir_create => x10za_a1w_f,             &
                               nagad_a1w_ir_interpret_adjoint_sparse,          &
                               nagad_a1w_ir_register_variable,                 &
                               nagad_a1w_ir_remove, nagad_a1w_ir_zero_adjoints &
                               , nagad_a1w_w_rtype, x10aa_a1w_f, x10ab_a1w_f,  &
                               Assignment (=)
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Type (nagad_a1w_w_rtype)         :: p, rho, x, y
      Real (Kind=nag_wp)               :: dpdr, dpdx, dpdy, rhor, xr, yr
      Integer                          :: i, ifail, n
!     .. Executable Statements ..
      Write (nout,*) 'G01HA_A1W_F Example Program Results'

!     Create AD tape
      Call nagad_a1w_ir_create

!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      Write (nout,*)
      Write (nout,*) 'Lower tail probablities and derivatives'
      Write (nout,*)
      Write (nout,99998) 'x', 'y', 'rho', 'p', 'dp/dx', 'dp/dy', 'dp/drho'

!     Create AD configuration data object
      ifail = 0
      Call x10aa_a1w_f(ad_handle,ifail)

      Do i = 1, n

        Read (nin,*) xr, yr, rhor
        x = xr
        y = yr
        rho = rhor

!       Register variables to differentiate w.r.t.
        Call nagad_a1w_ir_register_variable(x)
        Call nagad_a1w_ir_register_variable(y)
        Call nagad_a1w_ir_register_variable(rho)

        ifail = 0
        Call g01ha_a1w_f(ad_handle,x,y,rho,p,ifail)

        Call nagad_a1w_ir_zero_adjoints
        Call nagad_a1w_inc_derivative(p,1.0_nag_wp)
        ifail = 0
        Call nagad_a1w_ir_interpret_adjoint_sparse(ifail)

!       Get derivatives
        dpdx = nagad_a1w_get_derivative(x)
        dpdy = nagad_a1w_get_derivative(y)
        dpdr = nagad_a1w_get_derivative(rho)

        Write (nout,99999) x%value, y%value, rho%value, p%value, dpdx, dpdy,   &
          dpdr
      End Do
99999 Format (1X,1P,7E11.2)
99998 Format (1X,A4,A11,A13,A9,A15,A11,A13)

!     Remove computational data object and tape
      Call x10ab_a1w_f(ad_handle,ifail)
      Call nagad_a1w_ir_remove

    End Program g01ha_a1w_fe