Program f08vgfe

!     F08VGF Example Program Text

!     Mark 30.2 Release. NAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: dggsvp3, f06raf, f08yef, nag_wp, x02ajf, x04cbf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: eps, tola, tolb
      Integer                          :: i, ifail, info, irank, j, k, l, lda, &
                                          ldb, ldq, ldu, ldv, lwork, m, n,     &
                                          ncycle, p
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: a(:,:), alpha(:), b(:,:), beta(:),   &
                                          q(:,:), tau(:), u(:,:), v(:,:),      &
                                          work(:)
      Real (Kind=nag_wp)               :: wdum(1)
      Integer, Allocatable             :: iwork(:)
      Character (1)                    :: clabs(1), rlabs(1)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: max, nint, real
!     .. Executable Statements ..
      Write (nout,*) 'F08VGF Example Program Results'
      Write (nout,*)
      Flush (nout)

!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) m, n, p
      lda = m
      ldb = p
      ldq = n
      ldu = m
      ldv = p
      Allocate (a(lda,n),alpha(n),b(ldb,n),beta(n),q(ldq,n),tau(n),u(ldu,m),   &
        v(ldv,p),iwork(n))

!     Perform workspace query to get optimal size of work
!     The NAG name equivalent of dggsvp3 is f08vgf
      lwork = -1
      Call dggsvp3('U','V','Q',m,p,n,a,lda,b,ldb,tola,tolb,k,l,u,ldu,v,ldv,q,  &
        ldq,iwork,tau,wdum,lwork,info)
      lwork = nint(wdum(1))
      Allocate (work(lwork))

!     Read the m by n matrix A and p by n matrix B from data file

      Read (nin,*)(a(i,1:n),i=1,m)
      Read (nin,*)(b(i,1:n),i=1,p)

!     Compute tola and tolb as
!         tola = max(m,n)*norm(A)*macheps
!         tolb = max(p,n)*norm(B)*macheps

      eps = x02ajf()
      tola = real(max(m,n),kind=nag_wp)*f06raf('One-norm',m,n,a,lda,work)*eps
      tolb = real(max(p,n),kind=nag_wp)*f06raf('One-norm',p,n,b,ldb,work)*eps

!     Compute the factorization of (A, B)
!         (A = U*S*(Q**T), B = V*T*(Q**T))

!     The NAG name equivalent of dggsvp3 is f08vgf
      Call dggsvp3('U','V','Q',m,p,n,a,lda,b,ldb,tola,tolb,k,l,u,ldu,v,ldv,q,  &
        ldq,iwork,tau,work,lwork,info)

!     Given the factors above find the generalized SVD of (A, B)

!     The NAG name equivalent of dtgdja is f08yef
      Call f08yef('U','V','Q',m,p,n,k,l,a,lda,b,ldb,tola,tolb,alpha,beta,u,    &
        ldu,v,ldv,q,ldq,work,ncycle,info)

!     Print solution

      irank = k + l
      Write (nout,*) 'Number of infinite generalized singular values (k)'
      Write (nout,99999) k
      Write (nout,*) 'Number of finite generalized singular values (l)'
      Write (nout,99999) l
      Write (nout,*) 'Effective Numerical rank of (A; B) (k+l)'
      Write (nout,99999) irank
      Write (nout,*)
      Write (nout,*) 'Finite generalized singular values'
      Write (nout,99998)(alpha(j)/beta(j),j=k+1,irank)

      Write (nout,*)
      Flush (nout)

      Call x04cbf('General',' ',m,m,u,ldu,'1P,E12.4','Orthogonal matrix U',    &
        'Integer',rlabs,'Integer',clabs,80,0,ifail)

      Write (nout,*)
      Flush (nout)

      Call x04cbf('General',' ',p,p,v,ldv,'1P,E12.4','Orthogonal matrix V',    &
        'Integer',rlabs,'Integer',clabs,80,0,ifail)

      Write (nout,*)
      Flush (nout)

      Call x04cbf('General',' ',n,n,q,ldq,'1P,E12.4','Orthogonal matrix Q',    &
        'Integer',rlabs,'Integer',clabs,80,0,ifail)

      Write (nout,*)
      Flush (nout)

      Call x04cbf('Upper triangular','Non-unit',irank,irank,a(1,n-irank+1),    &
        lda,'1P,E12.4','Nonsingular upper triangular matrix R','Integer',      &
        rlabs,'Integer',clabs,80,0,ifail)

      Write (nout,*)
      Write (nout,*) 'Number of cycles of the Kogbetliantz method'
      Write (nout,99999) ncycle

99999 Format (1X,I5)
99998 Format (3X,8(1P,E12.4))
    End Program f08vgfe