Program f07tufe

!     F07TUF Example Program Text

!     Mark 30.3 Release. nAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: nag_wp, x02ajf, ztrcon
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
      Character (1), Parameter         :: diag = 'N', norm = '1'
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: rcond
      Integer                          :: i, info, lda, n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: a(:,:), work(:)
      Real (Kind=nag_wp), Allocatable  :: rwork(:)
!     .. Executable Statements ..
      Write (nout,*) 'F07TUF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      lda = n
      Allocate (a(lda,n),work(2*n),rwork(n))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)(a(i,i:n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)(a(i,1:i),i=1,n)
      End If

!     Estimate condition number
!     The NAG name equivalent of ztrcon is f07tuf
      Call ztrcon(norm,uplo,diag,n,a,lda,rcond,work,rwork,info)

      Write (nout,*)
      If (rcond>=x02ajf()) Then
        Write (nout,99999) 'Estimate of condition number =', 1.0_nag_wp/rcond
      Else
        Write (nout,*) 'A is singular to working precision'
      End If

99999 Format (1X,A,1P,E10.2)
    End Program f07tufe