Program f07hufe

!     F07HUF Example Program Text

!     Mark 30.2 Release. NAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: nag_wp, x02ajf, zlanhb => f06uef, zpbcon, zpbtrf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: anorm, rcond
      Integer                          :: i, info, j, kd, ldab, n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: ab(:,:), work(:)
      Real (Kind=nag_wp), Allocatable  :: rwork(:)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: max, min
!     .. Executable Statements ..
      Write (nout,*) 'F07HUF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n, kd
      ldab = kd + 1
      Allocate (ab(ldab,n),work(2*n),rwork(n))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Do i = 1, n
          Read (nin,*)(ab(kd+1+i-j,j),j=i,min(n,i+kd))
        End Do
      Else If (uplo=='L') Then
        Do i = 1, n
          Read (nin,*)(ab(1+i-j,j),j=max(1,i-kd),i)
        End Do
      End If

!     Compute norm of A
!     f06uef is the NAG name equivalent of the LAPACK auxiliary zlanhb
      anorm = zlanhb('1-norm',uplo,n,kd,ab,ldab,rwork)

!     Factorize A
!     The NAG name equivalent of zpbtrf is f07hrf
      Call zpbtrf(uplo,n,kd,ab,ldab,info)

      Write (nout,*)
      If (info==0) Then

!       Estimate condition number
!       The NAG name equivalent of zpbcon is f07huf
        Call zpbcon(uplo,n,kd,ab,ldab,anorm,rcond,work,rwork,info)

        If (rcond>=x02ajf()) Then
          Write (nout,99999) 'Estimate of condition number =',                 &
            1.0_nag_wp/rcond
        Else
          Write (nout,*) 'A is singular to working precision'
        End If
      Else
        Write (nout,*) 'A is not positive definite'
      End If

99999 Format (1X,A,1P,E10.2)
    End Program f07hufe