Program f07cgfe

!     F07CGF Example Program Text

!     Mark 30.3 Release. nAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: dgtcon, dgttrf, f06rnf, nag_wp, x02ajf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: anorm, rcond
      Integer                          :: info, n
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: d(:), dl(:), du(:), du2(:), work(:)
      Integer, Allocatable             :: ipiv(:), iwork(:)
!     .. Executable Statements ..
      Write (nout,*) 'F07CGF Example Program Results'
      Write (nout,*)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      Allocate (d(n),dl(n-1),du(n-1),du2(n-2),work(2*n),ipiv(n),iwork(n))

!     Read the tridiagonal matrix A from data file

      Read (nin,*) du(1:n-1)
      Read (nin,*) d(1:n)
      Read (nin,*) dl(1:n-1)

!     Compute the 1-norm of A
      anorm = f06rnf('1-norm',n,dl,d,du)

!     Factorize the tridiagonal matrix A
!     The NAG name equivalent of dgttrf is f07cdf
      Call dgttrf(n,dl,d,du,du2,ipiv,info)

      If (info==0) Then

!       Estimate the condition number of A
!       The NAG name equivalent of dgtcon is f07cgf
        Call dgtcon('1-norm',n,dl,d,du,du2,ipiv,anorm,rcond,work,iwork,info)

!       Print the estimated condition number

        If (rcond>=x02ajf()) Then
          Write (nout,99999) 'Estimate of condition number = ',                &
            1.0_nag_wp/rcond
        Else
          Write (nout,99999) 'A is singular to working precision. RCOND = ',   &
            rcond
        End If

      Else
        Write (nout,99998) 'The (', info, ',', info, ')',                      &
          ' element of the factor U is zero'
      End If

99999 Format (1X,A,1P,E10.2)
99998 Format (1X,A,I3,A,I3,A,A)
    End Program f07cgfe