Program f07ar_a1w_fe

!     F07AR_A1W_F Example Program Text
!     Mark 30.3 Release. NAG Copyright 2024.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: f07ar_a1w_f, f07aw_a1w_f,                       &
                               nagad_a1w_get_derivative,                       &
                               nagad_a1w_inc_derivative,                       &
                               nagad_a1w_ir_create => x10za_a1w_f,             &
                               nagad_a1w_ir_interpret_adjoint_sparse,          &
                               nagad_a1w_ir_register_variable,                 &
                               nagad_a1w_ir_remove, nagad_a1w_ir_zero_adjoints &
                               , nagad_a1w_w_ctype, x10aa_a1w_f, x10ab_a1w_f,  &
                               Assignment (=)
      Use nag_library, Only: nag_wp, x04daf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Integer                          :: i, ifail, j, lwork, n
!     .. Local Arrays ..
      Type (nagad_a1w_w_ctype), Allocatable :: a(:,:), a_in(:,:), work(:)
      Complex (Kind=nag_wp), Allocatable :: ar(:,:), da(:,:)
      Integer, Allocatable             :: ipiv(:)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: cmplx
!     .. Executable Statements ..
      Write (nout,*) 'F07AR_A1W_F Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      lwork = 64*n
      Allocate (a(n,n),a_in(n,n),ipiv(n))
      Allocate (ar(n,n),da(n,n),work(lwork))

!     Read A from data file
      Read (nin,*)(ar(i,1:n),i=1,n)
      a_in = ar

!     Create AD tape
      Call nagad_a1w_ir_create

!     Create AD configuration data object
      ifail = 0
      Call x10aa_a1w_f(ad_handle,ifail)

!     Register variables to differentiate w.r.t.
      Do i = 1, n
        Call nagad_a1w_ir_register_variable(a_in(i,i)%vreal)
        Call nagad_a1w_ir_register_variable(a_in(i,i)%vimag)
      End Do

      a = a_in

!     Factorize A
      ifail = 0
      Call f07ar_a1w_f(ad_handle,n,n,a,n,ipiv,ifail)

      Write (nout,*)
      Flush (nout)

!     Compute inverse
      Call f07aw_a1w_f(ad_handle,n,a,n,ipiv,work,lwork,ifail)

!     Print solution
      ar(1:n,1:n) = a(1:n,1:n)

!     ifail: behaviour on error exit
!            =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call x04daf('General',' ',n,n,ar,n,'Inverse',ifail)

      Write (nout,*)
      Write (nout,*) ' Derivatives calculated: First order adjoints'
      Write (nout,*) ' Computational mode    : algorithmic'

      Write (nout,*)
      Write (nout,*) ' Derivatives of inverse diagonal w.r.t. diagonal of A'
      Write (nout,*)
!     Setup evaluation of derivatives via adjoints
      Do i = 1, n
        Call nagad_a1w_ir_zero_adjoints
        Call nagad_a1w_inc_derivative(a(i,i)%vreal,1.0_nag_wp)
        ifail = 0
        Call nagad_a1w_ir_interpret_adjoint_sparse(ifail)

!       Get derivatives
        Do j = 1, n
          da(i,j) = cmplx(nagad_a1w_get_derivative(a_in(j,                     &
            j)%vreal),nagad_a1w_get_derivative(a_in(j,j)%vimag),kind=nag_wp)
        End Do
      End Do
      Call x04daf('General',' ',n,n,da,n,' d(real(inva(i,i)))/da(j,j)',ifail)
      Write (nout,*)
      Do i = 1, n
        Call nagad_a1w_ir_zero_adjoints
        Call nagad_a1w_inc_derivative(a(i,i)%vimag,1.0_nag_wp)
        ifail = 0
        Call nagad_a1w_ir_interpret_adjoint_sparse(ifail)

!       Get derivatives
        Do j = 1, n
          da(i,j) = cmplx(nagad_a1w_get_derivative(a_in(j,                     &
            j)%vreal),nagad_a1w_get_derivative(a_in(j,j)%vimag),kind=nag_wp)
        End Do
      End Do
      Call x04daf('General',' ',n,n,da,n,' d(imag(inva(i,i)))/da(j,j)',ifail)

!     Remove computational data object and tape
      Call x10ab_a1w_f(ad_handle,ifail)
      Call nagad_a1w_ir_remove

    End Program f07ar_a1w_fe