Program f07acfe

!     F07ACF Example Program Text

!     Mark 30.2 Release. NAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: dsgesv, nag_rp, nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, info, iter, lda, ldb, ldx, n, r
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: a(:,:), b(:,:), work(:), x(:,:)
      Real (Kind=nag_rp), Allocatable  :: swork(:)
      Integer, Allocatable             :: ipiv(:)
!     .. Executable Statements ..
      Write (nout,*) 'F07ACF Example Program Results'
      Write (nout,*)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n, r
      lda = n
      ldb = n
      ldx = n
      Allocate (a(lda,n),b(n,r),work(n*r),x(ldx,r),swork(n*(n+r)),ipiv(n))

!     Read A and B from data file

      Read (nin,*)(a(i,1:n),i=1,n)
      Read (nin,*)(b(i,1:r),i=1,n)

!     Solve the equations Ax = b for x

!     The NAG name equivalent of dsgesv is f07acf
      Call dsgesv(n,r,a,lda,ipiv,b,ldb,x,ldx,work,swork,iter,info)

      If (info==0) Then

!       Print solution

        Write (nout,*) 'Solution'
        Write (nout,99999)(x(i,1:r),i=1,n)

!       Print pivot indices

        Write (nout,*)
        Write (nout,*) 'Pivot indices'
        Write (nout,99998) ipiv(1:n)

      Else
        Write (nout,99997) 'The (', info, ',', info, ')',                      &
          ' element of the factor U is zero'
      End If

99999 Format ((3X,7F11.4))
99998 Format ((3X,7I11))
99997 Format (1X,A,I3,A,I3,A,A)
    End Program f07acfe