!   C05QC_P0W_F Example Program Text
!   Mark 30.3 Release. NAG Copyright 2024.
    Module c05qc_p0w_fe_mod

!     C05QC_P0W_F Example Program Module:
!            Parameters and User-defined Routines

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Accessibility Statements ..
      Private
      Public                           :: fcn
!     .. Parameters ..
      Integer, Parameter, Public       :: maxfev = 2000, ml = 1, mode = 2,     &
                                          mu = 1, n = 7, nout = 6, nprint = 0
    Contains
      Subroutine fcn(ad_handle,n,x,fvec,iuser,ruser,iflag)

!       .. Scalar Arguments ..
        Type (c_ptr), Intent (Inout)   :: ad_handle
        Integer, Intent (Inout)        :: iflag
        Integer, Intent (In)           :: n
!       .. Array Arguments ..
        Real (Kind=nag_wp), Intent (Inout) :: fvec(n), ruser(*)
        Real (Kind=nag_wp), Intent (In) :: x(n)
        Integer, Intent (Inout)        :: iuser(*)
!       .. Local Scalars ..
        Integer                        :: i
!       .. Executable Statements ..
        If (iflag==0) Then
          If (nprint>0) Then
!           Insert print statements here if desired.
            Continue
          End If
        Else
          Do i = 1, n
            fvec(i) = (ruser(2)+ruser(3)*x(i))*x(i) - ruser(5)
          End Do
          Do i = 2, n
            fvec(i) = fvec(i) + ruser(1)*x(i-1)
          End Do
          Do i = 1, n - 1
            fvec(i) = fvec(i) + ruser(4)*x(i+1)
          End Do
        End If
!       Set iflag negative to terminate execution for any reason.
        iflag = 0
        Return
      End Subroutine fcn
    End Module c05qc_p0w_fe_mod
    Program c05qc_p0w_fe
!     C05QC_P0W_F Example Main Program

!     .. Use Statements ..
      Use c05qc_p0w_fe_mod, Only: fcn, maxfev, ml, mode, mu, n, nout, nprint
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: c05qc_p0w_f
      Use nag_library, Only: nag_wp, x02ajf
!     .. Implicit None Statement ..
      Implicit None
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Real (Kind=nag_wp)               :: epsfcn, factor, xtol
      Integer                          :: i, ifail, nfev
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: diag(:), fjac(:,:), fvec(:), qtf(:), &
                                          r(:), x(:)
      Real (Kind=nag_wp)               :: ruser(5)
      Integer                          :: iuser(1)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: sqrt
!     .. Executable Statements ..

      Write (nout,*) 'C05QC_P0W_F Example Program Results'

      Allocate (diag(n),fjac(n,n),fvec(n),qtf(n),r(n*(n+1)/2),x(n))

!     The following starting values provide a rough solution.
      x(1:n) = -1.0_nag_wp

      ruser(1) = -1.0_nag_wp
      ruser(2) = 3.0_nag_wp
      ruser(3) = -2.0_nag_wp
      ruser(4) = -2.0_nag_wp
      ruser(5) = -1.0_nag_wp

      xtol = sqrt(x02ajf())
      epsfcn = 0.0_nag_wp
      factor = 100.0_nag_wp
      diag(1:n) = 1.0_nag_wp

      ifail = 0
      Call c05qc_p0w_f(ad_handle,fcn,n,x,fvec,xtol,maxfev,ml,mu,epsfcn,mode,   &
        diag,factor,nprint,nfev,fjac,r,qtf,iuser,ruser,ifail)

      Write (nout,*) 'Final approximate solution'
      Write (nout,99999)(x(i),i=1,n)
99999 Format (1X,3F12.4)

    End Program c05qc_p0w_fe