! F08PPF Example Program Text
! Mark 30.0 Release. NAG Copyright 2024.
Module f08ppfe_mod
! F08PPF Example Program Module:
! Parameters and User-defined Routines
! .. Use Statements ..
Use nag_library, Only: nag_wp
! .. Implicit None Statement ..
Implicit None
! .. Accessibility Statements ..
Private
Public :: select
! .. Parameters ..
Integer, Parameter, Public :: nb = 64, nin = 5, nout = 6
Logical, Parameter, Public :: check_fac = .True., &
print_cond = .False.
Contains
Function select(w)
! Logical function select for use with ZGEESX (F08PPF)
! Returns the value .TRUE. if the real part of the eigenvalue
! w is positive.
! .. Function Return Value ..
Logical :: select
! .. Scalar Arguments ..
Complex (Kind=nag_wp), Intent (In) :: w
! .. Intrinsic Procedures ..
Intrinsic :: real
! .. Executable Statements ..
select = (real(w)>0._nag_wp)
Return
End Function select
End Module f08ppfe_mod
Program f08ppfe
! F08PPF Example Main Program
! .. Use Statements ..
Use f08ppfe_mod, Only: check_fac, nb, nin, nout, print_cond, select
Use nag_library, Only: nag_wp, x02ajf, x04dbf, zgeesx, zgemm, &
zlange => f06uaf
! .. Implicit None Statement ..
Implicit None
! .. Local Scalars ..
Complex (Kind=nag_wp) :: alpha, beta
Real (Kind=nag_wp) :: anorm, eps, norm, rconde, rcondv, &
tol
Integer :: i, ifail, info, lda, ldc, ldd, ldvs, &
lwork, n, sdim
! .. Local Arrays ..
Complex (Kind=nag_wp), Allocatable :: a(:,:), c(:,:), d(:,:), vs(:,:), &
w(:), work(:)
Complex (Kind=nag_wp) :: dummy(1)
Real (Kind=nag_wp), Allocatable :: rwork(:)
Logical, Allocatable :: bwork(:)
Character (1) :: clabs(1), rlabs(1)
! .. Intrinsic Procedures ..
Intrinsic :: cmplx, max, nint, real
! .. Executable Statements ..
Write (nout,*) 'F08PPF Example Program Results'
Write (nout,*)
Flush (nout)
! Skip heading in data file
Read (nin,*)
Read (nin,*) n
lda = n
ldc = n
ldd = n
ldvs = n
Allocate (a(lda,n),c(ldc,n),d(ldd,n),vs(ldvs,n),w(n),rwork(n),bwork(n))
! Use routine workspace query to get optimal workspace.
lwork = -1
! The NAG name equivalent of zgeesx is f08ppf
Call zgeesx('Vectors (Schur)','Sort',select, &
'Both reciprocal condition numbers',n,a,lda,sdim,w,vs,ldvs,rconde, &
rcondv,dummy,lwork,rwork,bwork,info)
! Make sure that there is enough workspace for block size nb.
lwork = max(n*(nb+1+n/2),nint(real(dummy(1))))
Allocate (work(lwork))
! Read in the matrix A
Read (nin,*)(a(i,1:n),i=1,n)
! Copy A into D
d(1:n,1:n) = a(1:n,1:n)
! Print matrix A
! ifail: behaviour on error exit
! =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
ifail = 0
Call x04dbf('General',' ',n,n,a,lda,'Bracketed','F7.4','Matrix A', &
'Integer',rlabs,'Integer',clabs,80,0,ifail)
Write (nout,*)
Flush (nout)
! Find the Frobenius norm of A
! The NAG name equivalent of the LAPACK auxiliary zlange is f06uaf
anorm = zlange('Frobenius',n,n,a,lda,rwork)
! Find the Schur factorization of A
! The NAG name equivalent of zgeesx is f08ppf
Call zgeesx('Vectors (Schur)','Sort',select, &
'Both reciprocal condition numbers',n,a,lda,sdim,w,vs,ldvs,rconde, &
rcondv,work,lwork,rwork,bwork,info)
If (info/=0 .And. info/=(n+2)) Then
Write (nout,99993) 'Failure in ZGEESX. INFO =', info
Go To 100
End If
If (check_fac) Then
! Compute A - Z*T*Z^H from the factorization of A and store in matrix D
! The NAG name equivalent of zgemm is f06zaf
alpha = cmplx(1,kind=nag_wp)
beta = cmplx(0,kind=nag_wp)
Call zgemm('N','N',n,n,n,alpha,vs,ldvs,a,lda,beta,c,ldc)
alpha = cmplx(-1,kind=nag_wp)
beta = cmplx(1,kind=nag_wp)
Call zgemm('N','C',n,n,n,alpha,c,ldc,vs,ldvs,beta,d,ldd)
! Find norm of matrix D and print warning if it is too large
! f06uaf is the NAG name equivalent of the LAPACK auxiliary zlange
norm = zlange('O',ldd,n,d,ldd,rwork)
If (norm>x02ajf()**0.5_nag_wp) Then
Write (nout,*) 'Norm of A-(Z*T*Z^H) is much greater than 0.'
Write (nout,*) 'Schur factorization has failed.'
Go To 100
End If
End If
! Print solution
Write (nout,99999) 'Number of eigenvalues for which SELECT is true = ', &
sdim, '(dimension of invariant subspace)'
Write (nout,*)
! Print eigenvalues.
Write (nout,*) 'Selected eigenvalues'
Write (nout,99998)(i,w(i),i=1,sdim)
Write (nout,*)
If (info==(n+2)) Then
Write (nout,99997) '***Note that rounding errors mean ', &
'that leading eigenvalues in the Schur form', &
'no longer satisfy SELECT = .TRUE.'
Write (nout,*)
End If
Flush (nout)
If (print_cond) Then
! Print out the reciprocal condition numbers
Write (nout,99996) 'Reciprocal of projection norm onto the invariant', &
'subspace for the selected eigenvalues', 'RCONDE = ', rconde
Write (nout,*)
Write (nout,99995) &
'Reciprocal condition number for the invariant subspace', &
'RCONDV = ', rcondv
! Compute the machine precision
eps = x02ajf()
tol = eps*anorm
! Print out the approximate asymptotic error bound on the
! average absolute error of the selected eigenvalues given by
! eps*norm(A)/RCONDE
Write (nout,*)
Write (nout,99994) 'Approximate asymptotic error bound for selected ', &
'eigenvalues = ', tol/rconde
! Print out an approximate asymptotic bound on the maximum
! angular error in the computed invariant subspace given by
! eps*norm(A)/RCONDV
Write (nout,99994) &
'Approximate asymptotic error bound for the invariant ', &
'subspace = ', tol/rcondv
End If
100 Continue
99999 Format (1X,A,I4,/,1X,A)
99998 Format (1X,I4,2X,' (',F7.4,',',F7.4,')',:)
99997 Format (1X,2A,/,1X,A)
99996 Format (1X,A,/,1X,A,/,1X,A,1P,E8.1)
99995 Format (1X,A,/,1X,A,1P,E8.1)
99994 Format (1X,2A,1P,E8.1)
99993 Format (1X,A,I4)
End Program f08ppfe