Program f08hpfe

!     F08HPF Example Program Text

!     Mark 30.0 Release. NAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: nag_wp, x04daf, zhbevx
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Real (Kind=nag_wp), Parameter    :: zero = 0.0E+0_nag_wp
      Integer, Parameter               :: nin = 5, nout = 6
      Character (1), Parameter         :: uplo = 'U'
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: abstol, vl, vu
      Integer                          :: i, ifail, il, info, iu, j, kd, ldab, &
                                          ldq, ldz, m, n
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: ab(:,:), q(:,:), work(:), z(:,:)
      Real (Kind=nag_wp), Allocatable  :: rwork(:), w(:)
      Integer, Allocatable             :: iwork(:), jfail(:)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: max, min
!     .. Executable Statements ..
      Write (nout,*) 'F08HPF Example Program Results'
      Write (nout,*)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n, kd
      ldab = kd + 1
      ldq = n
      ldz = n
      m = n
      Allocate (ab(ldab,n),q(ldq,n),work(n),z(ldz,m),rwork(7*n),w(n),          &
        iwork(5*n),jfail(n))

!     Read the lower and upper bounds of the interval to be searched,
!     and read the upper or lower triangular part of the matrix A
!     from data file

      Read (nin,*) vl, vu
      If (uplo=='U') Then
        Read (nin,*)((ab(kd+1+i-j,j),j=i,min(n,i+kd)),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)((ab(1+i-j,j),j=max(1,i-kd),i),i=1,n)
      End If

!     Set the absolute error tolerance for eigenvalues.  With ABSTOL
!     set to zero, the default value is used instead

      abstol = zero

!     Solve the band symmetric eigenvalue problem
!     The NAG name equivalent of zhbevx is f08hpf
      Call zhbevx('Vectors','Values in range',uplo,n,kd,ab,ldab,q,ldq,vl,vu,   &
        il,iu,abstol,m,w,z,ldz,work,rwork,iwork,jfail,info)

      If (info>=0) Then

!       Print solution

        Write (nout,99999) 'Number of eigenvalues found =', m
        Write (nout,*)
        Write (nout,*) 'Eigenvalues'
        Write (nout,99998) w(1:m)
        Flush (nout)

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call x04daf('General',' ',n,m,z,ldz,'Selected eigenvectors',ifail)

        If (info>0) Then
          Write (nout,99999) 'INFO eigenvectors failed to converge, INFO =',   &
            info
          Write (nout,*) 'Indices of eigenvectors that did not converge'
          Write (nout,99997) jfail(1:m)
        End If
      Else
        Write (nout,99999) 'Failure in ZHBEVX. INFO =', info
      End If

99999 Format (1X,A,I5)
99998 Format (3X,(8F8.4))
99997 Format (3X,(8I8))
    End Program f08hpfe