Program f07jufe

!     F07JUF Example Program Text

!     Mark 30.0 Release. NAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: f06upf, nag_wp, x02ajf, zptcon, zpttrf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: anorm, rcond
      Integer                          :: info, n
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: e(:)
      Real (Kind=nag_wp), Allocatable  :: d(:), rwork(:)
!     .. Executable Statements ..
      Write (nout,*) 'F07JUF Example Program Results'
      Write (nout,*)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      Allocate (e(n-1),d(n),rwork(n))

!     Read the lower bidiagonal part of the tridiagonal matrix A from
!     data file

      Read (nin,*) d(1:n)
      Read (nin,*) e(1:n-1)

!     Compute the 1-norm of A
      anorm = f06upf('1-norm',n,d,e)

!     Factorize the tridiagonal matrix A
!     The NAG name equivalent of zpttrf is f07jrf
      Call zpttrf(n,d,e,info)

      If (info==0) Then

!       Estimate the condition number of A
!       The NAG name equivalent of zptcon is f07juf
        Call zptcon(n,d,e,anorm,rcond,rwork,info)

!       Print the estimated condition number

        If (rcond>=x02ajf()) Then
          Write (nout,99999) 'Estimate of condition number = ',                &
            1.0E0_nag_wp/rcond
        Else
          Write (nout,99999) 'A is singular to working precision. RCOND = ',   &
            rcond
        End If

      Else
        Write (nout,99998) 'The leading minor of order ', info,                &
          ' is not positive definite'
      End If

99999 Format (1X,A,1P,E10.2)
99998 Format (1X,A,I3,A)
    End Program f07jufe