Program f07bdfe

!     F07BDF Example Program Text

!     Mark 30.0 Release. NAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: dgbtrf, nag_wp, x04cef
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, ifail, info, j, k, kl, ku, ldab,  &
                                          m, n
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: ab(:,:)
      Integer, Allocatable             :: ipiv(:)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: max, min
!     .. Executable Statements ..
      Write (nout,*) 'F07BDF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) m, n, kl, ku
      ldab = 2*kl + ku + 1
      Allocate (ab(ldab,n),ipiv(n))

!     Read A from data file

      k = kl + ku + 1
      Read (nin,*)((ab(k+i-j,j),j=max(i-kl,1),min(i+ku,n)),i=1,m)

!     Factorize A
!     The NAG name equivalent of dgbtrf is f07bdf
      Call dgbtrf(m,n,kl,ku,ab,ldab,ipiv,info)

!     Print details of factorization

      Write (nout,*)
      Flush (nout)

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call x04cef(m,n,kl,kl+ku,ab,ldab,'Details of factorization',ifail)

!     Print pivot indices

      Write (nout,*)
      Write (nout,*) 'IPIV'
      Write (nout,99999) ipiv(1:min(m,n))

      If (info/=0) Then
        Write (nout,*) 'The factor U is singular'
      End If

99999 Format ((3X,7I11))
    End Program f07bdfe