Program e04mgfe

!     E04MGF Example Program Text

!     Mark 30.0 Release. NAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: e04mff, e04mgf, e04mhf, nag_wp, x04abf, x04acf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: iset = 1, nin = 5, ninopt = 7,       &
                                          nout = 6
      Character (*), Parameter         :: fname = 'e04mgfe.opt'
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: obj
      Integer                          :: i, ifail, inform, iter, j, lda,      &
                                          liwork, lwork, mode, n, nclin,       &
                                          outchn, sda
      Logical                          :: verbose_output
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: a(:,:), ax(:), bl(:), bu(:),         &
                                          clamda(:), cvec(:), work(:), x(:)
      Integer, Allocatable             :: istate(:), iwork(:)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: max
!     .. Executable Statements ..
      Write (nout,*) 'E04MGF Example Program Results'
      Flush (nout)

!     Skip heading in data file
      Read (nin,*)

      Read (nin,*) n, nclin

      liwork = 2*n + 3

!     The minimum LWORK for an LP problem:

      If (0<nclin .And. nclin<n) Then
        lwork = 2*(nclin+1)**2 + 7*n + 5*nclin
      Else If (nclin>=n) Then
        lwork = 2*n**2 + 7*n + 5*nclin
      Else
        lwork = 7*n + 1
      End If

      lda = max(1,nclin)

      If (nclin>0) Then
        sda = n
      Else
        sda = 1
      End If

      Allocate (istate(n+nclin),iwork(liwork),a(lda,sda),bl(n+nclin),          &
        bu(n+nclin),cvec(n),x(n),ax(max(1,nclin)),clamda(n+nclin),work(lwork))

      Read (nin,*) cvec(1:n)
      Read (nin,*)(a(i,1:sda),i=1,nclin)
      Read (nin,*) bl(1:(n+nclin))
      Read (nin,*) bu(1:(n+nclin))
      Read (nin,*) x(1:n)

!     Set the unit number for advisory messages to OUTCHN

      outchn = nout
      Call x04abf(iset,outchn)

!     Set this to .True. to cause e04nqf to produce intermediate
!     progress output
      verbose_output = .False.

      If (.Not. verbose_output) Then
!       Turn off intermediate output from e04mff - it is on by default
        Call e04mhf('Print Level = 0')
      End If

!     Set some other options using E04MHF

      Call e04mhf('Check Frequency = 10')

      Call e04mhf('Infinite Bound Size = 1.0D+25')

!     Open the options file for reading

      mode = 0

      ifail = 0
      Call x04acf(ninopt,fname,mode,ifail)

!     Read the options file for the remaining options

      Call e04mgf(ninopt,inform)

      If (inform/=0) Then
        Write (nout,99999) 'E04MGF terminated with INFORM = ', inform
        Go To 100
      End If

!     Solve the problem

      ifail = 0
      Call e04mff(n,nclin,a,lda,bl,bu,cvec,istate,x,iter,obj,ax,clamda,iwork,  &
        liwork,work,lwork,ifail)

      Select Case (ifail)
      Case (0:5,7:)
        Write (nout,*)
        Write (nout,99998)
        Do i = 1, n
          Write (nout,99997) i, istate(i), x(i), clamda(i)
        End Do

        If (nclin>0) Then
          Write (nout,*)
          Write (nout,99996)
          Do i = n + 1, n + nclin
            j = i - n
            Write (nout,99995) j, istate(i), ax(j), clamda(i)
          End Do

        End If

        Write (nout,*)
        Write (nout,99994) obj
      End Select

100   Continue

99999 Format (1X,A,I5)
99998 Format (1X,'Varbl',3X,'Istate',4X,'Value',9X,'Lagr Mult')
99997 Format (1X,'V',2(1X,I3),4X,1P,E14.3,2X,1P,E12.3)
99996 Format (1X,'L Con',3X,'Istate',4X,'Value',9X,'Lagr Mult')
99995 Format (1X,'L',2(1X,I3),4X,1P,E14.3,2X,1P,E12.3)
99994 Format (1X,'Final objective value = ',1P,E15.3)
    End Program e04mgfe