!   D02PU_P0W_F Example Program Text
!   Mark 30.0 Release. NAG Copyright 2024.

    Module d02pu_p0w_fe_mod

!     D02PU_P0W_F Example Program Module:
!            Parameters and User-defined Routines

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Accessibility Statements ..
      Private
      Public                           :: f
!     .. Parameters ..
      Integer, Parameter, Public       :: liwsav = 130, n = 4, nin = 5,        &
                                          nout = 6
      Integer, Parameter, Public       :: lrwsav = 350 + 32*n
    Contains

      Subroutine f(ad_handle,t,n,y,yp,iuser,ruser)
!       .. Implicit None Statement ..
        Implicit None
!       .. Scalar Arguments ..
        Type (c_ptr), Intent (Inout)   :: ad_handle
        Real (Kind=nag_wp), Intent (In) :: t
        Integer, Intent (In)           :: n
!       .. Array Arguments ..
        Real (Kind=nag_wp), Intent (Inout) :: ruser(*)
        Real (Kind=nag_wp), Intent (In) :: y(n)
        Real (Kind=nag_wp), Intent (Out) :: yp(n)
        Integer, Intent (Inout)        :: iuser(*)
!       .. Local Scalars ..
        Real (Kind=nag_wp)             :: r
!       .. Intrinsic Procedures ..
        Intrinsic                      :: sqrt
!       .. Executable Statements ..
        r = 1.0_nag_wp/sqrt(y(1)*y(1)+y(2)*y(2))
        r = r**3
        yp(1) = y(3)
        yp(2) = y(4)
        yp(3) = -y(1)*r
        yp(4) = -y(2)*r
        Return
      End Subroutine f
    End Module d02pu_p0w_fe_mod

    Program d02pu_p0w_fe

!     D02PU_P0W_F Example Main Program

!     .. Use Statements ..
      Use d02pu_p0w_fe_mod, Only: f, liwsav, lrwsav, n, nin, nout
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: d02pe_p0w_f, d02pq_p0w_f, d02pt_p0w_f,          &
                               d02pu_p0w_f
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Real (Kind=nag_wp)               :: eps, errmax, hnext, hstart, tend,    &
                                          terrmx, tgot, tol, tstart, twant,    &
                                          waste
      Integer                          :: fevals, ifail, method, stepcost,     &
                                          stepsok
!     .. Local Arrays ..
      Real (Kind=nag_wp)               :: rmserr(n), ruser(1), thresh(n),      &
                                          y(n), ygot(n), ymax(n), ypgot(n)
      Real (Kind=nag_wp), Allocatable  :: rwsav(:)
      Integer                          :: iuser(1)
      Integer, Allocatable             :: iwsav(:)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: sqrt
!     .. Executable Statements ..
      Write (nout,*) 'D02PU_P0W_F Example Program Results'

      Allocate (iwsav(liwsav),rwsav(lrwsav))

!     Set initial conditions and input

!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) method
      Read (nin,*) tstart, tend
      Read (nin,*) eps
      Read (nin,*) hstart, tol
      Read (nin,*) thresh(1:n)

!     Set control for output

      y(1) = 1.0_nag_wp - eps
      y(2) = 0.0_nag_wp
      y(3) = 0.0_nag_wp
      y(4) = sqrt((1.0_nag_wp+eps)/(1.0_nag_wp-eps))

!     ifail: behaviour on error exit
!            =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call d02pq_p0w_f(ad_handle,n,tstart,tend,y,tol,thresh,method,hstart,     &
        iwsav,rwsav,ifail)

      Write (nout,99999) tol
      Write (nout,99998)
      Write (nout,99997) tstart, y(1:n)

      twant = tend

integ: Do

        ifail = -1
        Call d02pe_p0w_f(ad_handle,f,n,twant,tgot,ygot,ypgot,ymax,iuser,ruser, &
          iwsav,rwsav,ifail)

        If (ifail<2 .Or. ifail>4) Then
          Exit integ
        End If
      End Do integ

      If (ifail==0) Then
        Write (nout,99997) tgot, ygot(1:n)

!       Get error estimates
        ifail = 0
        Call d02pu_p0w_f(ad_handle,n,rmserr,errmax,terrmx,iwsav,rwsav,ifail)

        Write (nout,99996) rmserr(1:n)
        Write (nout,99995) errmax, terrmx

        ifail = 0
        Call d02pt_p0w_f(ad_handle,fevals,stepcost,waste,stepsok,hnext,iwsav,  &
          rwsav,ifail)
        Write (nout,99994) fevals
      End If

99999 Format (/,' Calculation with TOL = ',1P,E8.1)
99998 Format (/,'    t         y1         y2         y3         y4',/)
99997 Format (1X,F6.3,4(3X,F8.4))
99996 Format (/,' Componentwise error assessment',/,9X,4(2X,E9.2))
99995 Format (/,' Worst global error observed was ',E9.2,                      &
        ' - it occurred at T = ',F6.3)
99994 Format (/,' Cost of the integration in evaluations of F is',I6)

    End Program d02pu_p0w_fe