!   D01AMF Example Program Text
!   Mark 30.0 Release. NAG Copyright 2024.

    Module d01amfe_mod

!     D01AMF Example Program Module:
!            Parameters and User-defined Routines

!     .. Use Statements ..
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Accessibility Statements ..
      Private
      Public                           :: f
!     .. Parameters ..
      Integer, Parameter, Public       :: lw = 800, nout = 6
      Integer, Parameter, Public       :: liw = lw/4
    Contains
      Function f(x)

!       .. Function Return Value ..
        Real (Kind=nag_wp)             :: f
!       .. Scalar Arguments ..
        Real (Kind=nag_wp), Intent (In) :: x
!       .. Intrinsic Procedures ..
        Intrinsic                      :: sqrt
!       .. Executable Statements ..
        f = 1.0E0_nag_wp/((x+1.0E0_nag_wp)*sqrt(x))

        Return

      End Function f
    End Module d01amfe_mod
    Program d01amfe

!     D01AMF Example Main Program

!     .. Use Statements ..
      Use d01amfe_mod, Only: f, liw, lw, nout
      Use nag_library, Only: d01amf, nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: abserr, bound, epsabs, epsrel,       &
                                          result
      Integer                          :: ifail, inf
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: w(:)
      Integer, Allocatable             :: iw(:)
!     .. Executable Statements ..
      Write (nout,*) 'D01AMF Example Program Results'

      Allocate (w(lw),iw(liw))

      epsabs = 0.0E0_nag_wp
      epsrel = 1.0E-04_nag_wp
      bound = 0.0E0_nag_wp
      inf = 1

      ifail = -1
      Call d01amf(f,bound,inf,epsabs,epsrel,result,abserr,w,lw,iw,liw,ifail)

      If (ifail>=0) Then
        Write (nout,*)
        Write (nout,99999) 'A     ', 'lower limit of integration', bound
        Write (nout,99995) 'B     ', 'upper limit of integration', 'infinity'
        Write (nout,99998) 'EPSABS', 'absolute accuracy requested', epsabs
        Write (nout,99998) 'EPSREL', 'relative accuracy requested', epsrel
      End If

      If (ifail>=0 .And. ifail<=5) Then
        Write (nout,*)
        Write (nout,99997) 'RESULT', 'approximation to the integral', result
        Write (nout,99998) 'ABSERR', 'estimate of the absolute error', abserr
        Write (nout,99996) 'IW(1) ', 'number of subintervals used', iw(1)
      End If

99999 Format (1X,A6,' - ',A32,' = ',F10.4)
99998 Format (1X,A6,' - ',A32,' = ',E9.2)
99997 Format (1X,A6,' - ',A32,' = ',F9.5)
99996 Format (1X,A6,' - ',A32,' = ',I4)
99995 Format (1X,A6,' - ',A32,' = ',A8)
    End Program d01amfe