!   C05QS_P0W_F Example Program Text
!   Mark 30.0 Release. NAG Copyright 2024.
    Module c05qs_p0w_fe_mod

!     C05QS_P0W_F Example Program Module:
!            Parameters and User-defined Routines

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Accessibility Statements ..
      Private
      Public                           :: fcn
!     .. Parameters ..
      Integer, Parameter, Public       :: n = 7, nout = 6
    Contains
      Subroutine fcn(ad_handle,n,lindf,indf,x,fvec,iuser,ruser,iflag)

!       .. Scalar Arguments ..
        Type (c_ptr), Intent (Inout)   :: ad_handle
        Integer, Intent (Inout)        :: iflag
        Integer, Intent (In)           :: lindf, n
!       .. Array Arguments ..
        Real (Kind=nag_wp), Intent (Out) :: fvec(n)
        Real (Kind=nag_wp), Intent (Inout) :: ruser(*)
        Real (Kind=nag_wp), Intent (In) :: x(n)
        Integer, Intent (In)           :: indf(lindf)
        Integer, Intent (Inout)        :: iuser(*)
!       .. Local Scalars ..
        Integer                        :: i, ind
!       .. Executable Statements ..
        iflag = 0
        Do ind = 1, lindf
          i = indf(ind)
          fvec(i) = (ruser(2)+ruser(3)*x(i))*x(i) - ruser(5)
          If (i>1) Then
            fvec(i) = fvec(i) + ruser(1)*x(i-1)
          End If
          If (i<n) Then
            fvec(i) = fvec(i) + ruser(4)*x(i+1)
          End If
        End Do
      End Subroutine fcn
    End Module c05qs_p0w_fe_mod
    Program c05qs_p0w_fe
!     C05QS_P0W_F Example Main Program

!     .. Use Statements ..
      Use c05qs_p0w_fe_mod, Only: fcn, n, nout
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: c05qs_p0w_f
      Use nag_library, Only: nag_wp, x02ajf
!     .. Implicit None Statement ..
      Implicit None
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Real (Kind=nag_wp)               :: xtol
      Integer                          :: i, ifail, licomm, lrcomm
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: fvec(:), rcomm(:), x(:)
      Real (Kind=nag_wp)               :: ruser(5)
      Integer, Allocatable             :: icomm(:)
      Integer                          :: iuser(1)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: sqrt
!     .. Executable Statements ..

      Write (nout,*) 'C05QS_P0W_F Example Program Results'

      lrcomm = 12 + 3*n
      licomm = 8*n + 19 + 3*n

      Allocate (fvec(n),x(n),rcomm(lrcomm),icomm(licomm))

!     The following starting values provide a rough solution.
      x(1:n) = -1.0_nag_wp

      ruser(1) = -1.0_nag_wp
      ruser(2) = 3.0_nag_wp
      ruser(3) = -2.0_nag_wp
      ruser(4) = -2.0_nag_wp
      ruser(5) = -1.0_nag_wp

      xtol = sqrt(x02ajf())

      ifail = 0
      Call c05qs_p0w_f(ad_handle,fcn,n,x,fvec,xtol,.True.,rcomm,lrcomm,icomm,  &
        licomm,iuser,ruser,ifail)

      Write (nout,*) 'Final approximate solution'
      Write (nout,99999)(x(i),i=1,n)
99999 Format (1X,3F12.4)

    End Program c05qs_p0w_fe