Program g02bbfe

!     G02BBF Example Program Text

!     Mark 30.3 Release. nAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: g02bbf, nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, ifail, ldr, ldssp, ldx, m, n,     &
                                          ncases
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: r(:,:), ssp(:,:), std(:), x(:,:),    &
                                          xbar(:), xmiss(:)
      Integer, Allocatable             :: miss(:)
!     .. Executable Statements ..
      Write (nout,*) 'G02BBF Example Program Results'
      Write (nout,*)

!     Skip heading in data file
      Read (nin,*)

!     Read in the problem size
      Read (nin,*) n, m

      ldr = m
      ldssp = m
      ldx = n
      Allocate (x(ldx,m),r(ldr,m),ssp(ldssp,m),std(m),xbar(m),xmiss(m),        &
        miss(m))

!     Read in data
      Read (nin,*)(x(i,1:m),i=1,n)

!     Read in missing value flags
      Read (nin,*) miss(1:m)
      Read (nin,*) xmiss(1:m)

!     Display data
      Write (nout,99999) 'Number of variables (columns) =', m
      Write (nout,99999) 'Number of cases     (rows)    =', n
      Write (nout,*)
      Write (nout,*) 'Data matrix is:-'
      Write (nout,*)
      Write (nout,99998)(i,i=1,m)
      Write (nout,99997)(i,x(i,1:m),i=1,n)
      Write (nout,*)

!     Calculate summary statistics
      ifail = 0
      Call g02bbf(n,m,x,ldx,miss,xmiss,xbar,std,ssp,ldssp,r,ldr,ncases,ifail)

!     Display results
      Write (nout,*) 'Variable   Mean    St. dev.'
      Write (nout,99996)(i,xbar(i),std(i),i=1,m)
      Write (nout,*)
      Write (nout,*) 'Sums of squares and cross-products of deviations'
      Write (nout,99998)(i,i=1,m)
      Write (nout,99997)(i,ssp(i,1:m),i=1,m)
      Write (nout,*)
      Write (nout,*) 'Correlation coefficients'
      Write (nout,99998)(i,i=1,m)
      Write (nout,99997)(i,r(i,1:m),i=1,m)
      Write (nout,*)
      Write (nout,99999) 'Number of cases actually used: ', ncases

99999 Format (1X,A,I5)
99998 Format (1X,6I12)
99997 Format (1X,I3,3F12.4)
99996 Format (1X,I5,2F11.4)
    End Program g02bbfe