Program f11bdfe

!     F11BDF Example Program Text

!     Mark 30.3 Release. nAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: f11bdf, f11bef, f11bff, f11daf, f11dbf, f11xaf,   &
                             nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: anorm, dtol, sigmax, stplhs, stprhs, &
                                          tol
      Integer                          :: i, ifail, ifail1, irevcm, iterm,     &
                                          itn, la, lfill, liwork, lwork,       &
                                          lwreq, m, maxitn, monit, n, nnz,     &
                                          nnzc, npivm
      Character (8)                    :: method
      Character (1)                    :: milu, norm, precon, pstrat, weight
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: a(:), b(:), wgt(:), work(:), x(:)
      Integer, Allocatable             :: icol(:), idiag(:), ipivp(:),         &
                                          ipivq(:), irow(:), istr(:), iwork(:)
!     .. Executable Statements ..
      Write (nout,*) 'F11BDF Example Program Results'

!     Skip heading in data file

      Read (nin,*)
      Read (nin,*) n
      Read (nin,*) nnz
      la = 3*nnz
      liwork = 7*n + 2
      lwork = 200
      Allocate (a(la),b(n),wgt(n),work(lwork),x(n),icol(la),idiag(n),ipivp(n), &
        ipivq(n),irow(la),istr(n+1),iwork(liwork))

!     Read or initialize the parameters for the iterative solver

      Read (nin,*) method
      Read (nin,*) precon, norm, weight, iterm
      Read (nin,*) m, tol, maxitn
      Read (nin,*) monit
      anorm = 0.0E0_nag_wp
      sigmax = 0.0E0_nag_wp

!     Read the parameters for the preconditioner

      Read (nin,*) lfill, dtol
      Read (nin,*) milu, pstrat

!     Read the nonzero elements of the matrix A

      Do i = 1, nnz
        Read (nin,*) a(i), irow(i), icol(i)
      End Do

!     Read right-hand side vector b and initial approximate solution

      Read (nin,*) b(1:n)
      Read (nin,*) x(1:n)

!     Calculate incomplete LU factorization

      milu = 'N'

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call f11daf(n,nnz,a,la,irow,icol,lfill,dtol,pstrat,milu,ipivp,ipivq,     &
        istr,idiag,nnzc,npivm,iwork,liwork,ifail)

!     Call F11BDF to initialize the solver

      ifail = 0
      Call f11bdf(method,precon,norm,weight,iterm,n,m,tol,maxitn,anorm,sigmax, &
        monit,lwreq,work,lwork,ifail)

!     Call repeatedly F11BEF to solve the equations
!     Note that the arrays B and X are overwritten

!     On final exit, X will contain the solution and B the
!     residual vector

      irevcm = 0
      lwreq = lwork

      ifail = 1
loop: Do
        Call f11bef(irevcm,x,b,wgt,work,lwreq,ifail)

        If (irevcm/=4) Then
          ifail1 = -1
          Select Case (irevcm)
          Case (-1)

            Call f11xaf('Transpose',n,nnz,a,irow,icol,'No checking',x,b,       &
              ifail1)

          Case (1)

            Call f11xaf('No transpose',n,nnz,a,irow,icol,'No checking',x,b,    &
              ifail1)

          Case (2)

            Call f11dbf('No transpose',n,a,la,irow,icol,ipivp,ipivq,istr,      &
              idiag,'No checking',x,b,ifail1)

          Case (3)

            ifail1 = 0
            Call f11bff(itn,stplhs,stprhs,anorm,sigmax,work,lwreq,ifail1)

            Write (nout,99999) itn, stplhs
            Write (nout,99998)
            Write (nout,99997)(x(i),b(i),i=1,n)
          End Select
          If (ifail1/=0) Then
            irevcm = 6
          End If
        Else If (ifail/=0) Then
          Write (nout,99993) ifail
          Go To 100
        Else
          Exit loop
        End If
      End Do loop

!     Obtain information about the computation

      ifail1 = 0
      Call f11bff(itn,stplhs,stprhs,anorm,sigmax,work,lwreq,ifail1)

!     Print the output data

      Write (nout,99996)
      Write (nout,99995) 'Number of iterations for convergence:    ', itn
      Write (nout,99994) 'Residual norm:                           ', stplhs
      Write (nout,99994) 'Right-hand side of termination criterion:', stprhs
      Write (nout,99994) '1-norm of matrix A:                      ', anorm

!     Output x

      Write (nout,99998)
      Write (nout,99997)(x(i),b(i),i=1,n)
100   Continue

99999 Format (/,1X,'Monitoring at iteration no.',I4,/,1X,1P,'residual no',     &
        'rm: ',E14.4)
99998 Format (/,2X,'  Solution vector',2X,' Residual vector')
99997 Format (1X,1P,E16.4,1X,E16.4)
99996 Format (/,1X,'Final Results')
99995 Format (1X,A,I4)
99994 Format (1X,A,1P,E14.4)
99993 Format (1X,/,1X,' ** F11BEF returned with IFAIL = ',I5)
    End Program f11bdfe