Program f08ggfe

!     F08GGF Example Program Text

!     Mark 30.3 Release. nAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: blas_damax_val, dopmtr, dsptrd, dstebz, dstein,   &
                             nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Real (Kind=nag_wp), Parameter    :: zero = 0.0E0_nag_wp
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: r, vl, vu
      Integer                          :: i, ifail, info, j, k, ldc, m, n,     &
                                          nsplit
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: ap(:), c(:,:), d(:), e(:), tau(:),   &
                                          w(:), work(:)
      Integer, Allocatable             :: iblock(:), ifailv(:), isplit(:),     &
                                          iwork(:)
!     .. Executable Statements ..
      Write (nout,*) 'F08GGF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      ldc = n
      Allocate (ap(n*(n+1)/2),c(ldc,n),d(n),e(n),tau(n),w(n),work(5*n),iblock( &
        n),ifailv(n),isplit(n),iwork(3*n))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)((ap(i+j*(j-1)/2),j=i,n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)((ap(i+(2*n-j)*(j-1)/2),j=1,i),i=1,n)
      End If

!     Reduce A to tridiagonal form T = (Q**T)*A*Q
!     The NAG name equivalent of dsptrd is f08gef
      Call dsptrd(uplo,n,ap,d,e,tau,info)

!     Calculate the two smallest eigenvalues of T (same as A)
!     The NAG name equivalent of dstebz is f08jjf
      Call dstebz('I','B',n,vl,vu,1,2,zero,d,e,m,nsplit,w,iblock,isplit,work,  &
        iwork,info)

      Write (nout,*)
      If (info>0) Then
        Write (nout,*) 'Failure to converge.'
      Else
        Write (nout,*) 'Eigenvalues'
        Write (nout,99999) w(1:m)

!       Calculate the eigenvectors of T, storing the result in C
!       The NAG name equivalent of dstein is f08jkf
        Call dstein(n,d,e,m,w,iblock,isplit,c,ldc,work,iwork,ifailv,info)

        If (info>0) Then
          Write (nout,*) 'Failure to converge.'
        Else

!         Calculate the eigenvectors of A = Q * (eigenvectors of T)
!         The NAG name equivalent of dopmtr is f08ggf
          Call dopmtr('Left',uplo,'No transpose',n,m,ap,tau,c,ldc,work,info)

!         Print eigenvectors
          Write (nout,*)
          Flush (nout)

!         Normalize the eigenvectors
          Do i = 1, m
            Call blas_damax_val(n,c(1,i),1,k,r)
            If (c(k,i)<zero) Then
              c(1:n,i) = -c(1:n,i)
            End If
          End Do

!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
          ifail = 0
          Call x04caf('General',' ',n,m,c,ldc,'Eigenvectors',ifail)

        End If
      End If

99999 Format (3X,(9F8.4))
    End Program f08ggfe