Program f08fffe

!     F08FFF Example Program Text

!     Mark 30.3 Release. nAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: blas_damax_val, dorgtr, dsteqr, dsytrd, f06qff,   &
                             nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Real (Kind=nag_wp), Parameter    :: zero = 0.0_nag_wp
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: r
      Integer                          :: i, ifail, info, k, lda, ldz, lwork,  &
                                          n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: a(:,:), d(:), e(:), tau(:), work(:), &
                                          z(:,:)
!     .. Executable Statements ..
      Write (nout,*) 'F08FFF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      lda = n
      ldz = n
      lwork = 64*n
      Allocate (a(lda,n),d(n),e(n),tau(n),work(lwork),z(ldz,n))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)(a(i,i:n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)(a(i,1:i),i=1,n)
      End If

!     Reduce A to tridiagonal form T = (Q**T)*A*Q
!     The NAG name equivalent of dsytrd is f08fef
      Call dsytrd(uplo,n,a,lda,d,e,tau,work,lwork,info)

!     Copy A into Z
      Call f06qff(uplo,n,n,a,lda,z,ldz)

!     Form Q explicitly, storing the result in Z
!     The NAG name equivalent of dorgtr is f08fff
      Call dorgtr(uplo,n,z,ldz,tau,work,lwork,info)

!     Calculate all the eigenvalues and eigenvectors of A
!     The NAG name equivalent of dsteqr is f08jef
      Call dsteqr('V',n,d,e,z,ldz,work,info)

      Write (nout,*)
      If (info>0) Then
        Write (nout,*) 'Failure to converge.'
      Else

!       Print eigenvalues and eigenvectors

        Write (nout,*) 'Eigenvalues'
        Write (nout,99999) d(1:n)
        Write (nout,*)
        Flush (nout)

!       Normalize the eigenvectors: largest element positive
        Do i = 1, n
          Call blas_damax_val(n,z(1,i),1,k,r)
          If (z(k,i)<zero) Then
            z(1:n,i) = -z(1:n,i)
          End If
        End Do

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call x04caf('General',' ',n,n,z,ldz,'Eigenvectors',ifail)

      End If

99999 Format (3X,(8F8.4))
    End Program f08fffe