Program f07fj_t1w_fe

!     F07FJ_T1W_F Example Program Text
!     Mark 30.3 Release. NAG Copyright 2024.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: f07fd_t1w_f, f07fj_t1w_f,                       &
                               nagad_t1w_set_derivative, nagad_t1w_w_rtype,    &
                               x10aa_t1w_f, x10ab_t1w_f, Assignment (=)
      Use nag_library, Only: nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Integer                          :: i, ifail, j, lda, n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Type (nagad_t1w_w_rtype), Allocatable :: a(:,:), ax(:,:)
      Real (Kind=nag_wp), Allocatable  :: ar(:,:), d(:,:)
!     .. Executable Statements ..
      Write (nout,*) 'F07FJ_T1W_F Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      lda = n
      Allocate (a(lda,n),ax(lda,n),ar(lda,n),d(n,n))

!     Read A from data file
      ar = 0.0_nag_wp
      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)(ar(i,i:n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)(ar(i,1:i),i=1,n)
      End If
      a = ar

!     Create AD configuration data object
      ifail = 0
      Call x10aa_t1w_f(ad_handle,ifail)

      Do i = 1, n
        Call nagad_t1w_set_derivative(a(i,i),1.0_nag_wp)
        ax = a

!       Factorize A
        ifail = 0
        Call f07fd_t1w_f(ad_handle,uplo,n,ax,lda,ifail)

!       Compute inverse of A
        ifail = 0
        Call f07fj_t1w_f(ad_handle,uplo,n,ax,lda,ifail)

        a(i,i)%tangent = 0.0_nag_wp
        Do j = 1, n
          d(j,i) = ax(j,j)%tangent
        End Do
      End Do

!     Print inverse
      ar(1:n,1:n) = ax(1:n,1:n)%value
      ifail = 0
      Call x04caf('General',' ',n,n,ar,n,'Inverse',ifail)

      Write (nout,*)
      Write (nout,*) ' Derivatives calculated: First order tangents'
      Write (nout,*) ' Computational mode    : algorithmic'

      Write (nout,*)
      Write (nout,*) ' Derivatives of Ainv_ii w.r.t. A_jj'
!     Setup evaluation of derivatives via adjoints

      Call x04caf('General',' ',n,n,d,n,'',ifail)

!     Remove computational data object
      Call x10ab_t1w_f(ad_handle,ifail)

    End Program f07fj_t1w_fe