!   D01RM_T1W_F Example Program Text
!   Mark 30.2 Release. NAG Copyright 2024.

    Module d01rm_t1w_fe_mod

!     .. Use Statements ..
      Use nagad_library, Only: nagad_t1w_w_rtype, sqrt, Operator (/),          &
                               Operator (*), Operator (+)
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Accessibility Statements ..
      Private
      Public                           :: f
!     .. Parameters ..
      Integer, Parameter, Public       :: nout = 6
    Contains
      Subroutine f(ad_handle,x,nx,fv,iflag,iuser,ruser,cpuser)
!       .. Use Statements ..
        Use, Intrinsic                 :: iso_c_binding, Only: c_ptr
!       .. Scalar Arguments ..
        Type (c_ptr), Intent (Inout)   :: ad_handle
        Type (c_ptr), Intent (In)      :: cpuser
        Integer, Intent (Inout)        :: iflag
        Integer, Intent (In)           :: nx
!       .. Array Arguments ..
        Type (nagad_t1w_w_rtype), Intent (Out) :: fv(nx)
        Type (nagad_t1w_w_rtype), Intent (Inout) :: ruser(*)
        Type (nagad_t1w_w_rtype), Intent (In) :: x(nx)
        Integer, Intent (Inout)        :: iuser(*)
!       .. Executable Statements ..
        fv = 1.0_nag_wp/((x+ruser(21))*sqrt(ruser(22)*x))
        Return
      End Subroutine f
    End Module d01rm_t1w_fe_mod

    Program d01rm_t1w_fe

!     D01RM_T1W_F Example Main Program

!     .. Use Statements ..
      Use d01rm_t1w_fe_mod, Only: f, nout
      Use, Intrinsic                   :: iso_c_binding, Only: c_null_ptr,     &
                                          c_ptr
      Use nagad_library, Only: d01rm_t1w_f, nagad_t1w_w_rtype, x10aa_t1w_f,    &
                               x10ab_t1w_f, Assignment (=)
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Local Scalars ..
      Type (nagad_t1w_w_rtype)         :: abserr, bound, epsabs, epsrel,       &
                                          result
      Type (c_ptr)                     :: ad_handle, cpuser
      Real (Kind=nag_wp)               :: dr1, dr2
      Integer                          :: ifail, inf, liinfo, lrinfo, maxsub
!     .. Local Arrays ..
      Type (nagad_t1w_w_rtype), Allocatable :: rinfo(:)
      Type (nagad_t1w_w_rtype)         :: ruser(22)
      Integer, Allocatable             :: iinfo(:)
      Integer                          :: iuser(1)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: max
!     .. Executable Statements ..

      Write (nout,*) 'D01RM_T1W_F Example Program Results'

!     Initialize AD types
      bound = 0.0_nag_wp
      epsabs = 0.0_nag_wp
      epsrel = 1.0E-4_nag_wp

      inf = 1
      maxsub = 20
      lrinfo = 4*maxsub
      liinfo = max(maxsub,4)

      Allocate (rinfo(lrinfo),iinfo(liinfo))

      iuser(1) = 0
      ruser(1:20) = 0.0_nag_wp
      ruser(21) = 1.0_nag_wp
      ruser(22) = 1.0_nag_wp
      cpuser = c_null_ptr

!     Create AD configuration data object
      ifail = 0
      Call x10aa_t1w_f(ad_handle,ifail)

!     Evaluate the integral using the AD routine
      ifail = -1
      ruser(21)%tangent = 1.0_nag_wp
      Call d01rm_t1w_f(ad_handle,f,bound,inf,epsabs,epsrel,maxsub,result,      &
        abserr,rinfo,iinfo,iuser,ruser,cpuser,ifail)
      ruser(21)%tangent = 0.0_nag_wp

      If (ifail<0) Then
        Write (nout,99999) 'The routine has failed with ifail = ', ifail
        Go To 100
99999   Format (1X,A,I0)
      End If
!     Print inputs and primal outputs
      Write (nout,*)
      Write (nout,99998) 'a        ', 'lower limit of integration',            &
        bound%value
      Write (nout,99994) 'b        ', 'upper limit of integration', 'Infinity'
      Write (nout,99997) 'epsabs   ', 'absolute accuracy requested',           &
        epsabs%value
      Write (nout,99997) 'epsrel   ', 'relative accuracy requested',           &
        epsrel%value
      Write (nout,99995) 'maxsub   ', 'max number of subintervals', maxsub
      Write (nout,*)
      If (ifail>=0) Then
        Write (nout,99996) 'result   ', 'approximation to the integral',       &
          result%value
        Write (nout,99997) 'abserr   ', 'estimate of the absolute error',      &
          abserr%value
        Write (nout,99995) 'iinfo(1) ', 'number of subintervals used',         &
          iinfo(1)
      End If
99998 Format (1X,A9,' - ',A32,' = ',F9.4)
99997 Format (1X,A9,' - ',A32,' = ',E9.2)
99996 Format (1X,A9,' - ',A32,' = ',F9.5)
99995 Format (1X,A9,' - ',A32,' = ',I4)
99994 Format (1X,A9,' - ',A32,' = ',A8)

      Write (nout,*)
      Write (nout,*) ' Derivatives calculated: First order tangents'
      Write (nout,*) ' Computational mode    : algorithmic'

!     Get derivatives
      dr1 = result%tangent

      ifail = -1
      ruser(22)%tangent = 1.0_nag_wp
      Call d01rm_t1w_f(ad_handle,f,bound,inf,epsabs,epsrel,maxsub,result,      &
        abserr,rinfo,iinfo,iuser,ruser,cpuser,ifail)

      dr2 = result%tangent

      Write (nout,*) ' Derivatives:'
      Write (nout,99993) 'd(result)/druser(21) =', dr1
      Write (nout,99993) 'd(result)/druser(22) =', dr2
99993 Format (1X,A22,1X,F10.5)

100   Continue
!     Remove computational data object
      Call x10ab_t1w_f(ad_handle,ifail)

    End Program d01rm_t1w_fe