Program g01fb_a1w_fe

!     G01FB_A1W_F Example Program Text
!     Mark 30.1 Release. NAG Copyright 2024.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: g01fb_a1w_f, nagad_a1w_get_derivative,          &
                               nagad_a1w_inc_derivative,                       &
                               nagad_a1w_ir_create => x10za_a1w_f,             &
                               nagad_a1w_ir_interpret_adjoint_sparse,          &
                               nagad_a1w_ir_register_variable,                 &
                               nagad_a1w_ir_remove, nagad_a1w_ir_zero_adjoints &
                               , nagad_a1w_w_rtype, x10aa_a1w_f, x10ab_a1w_f,  &
                               Assignment (=)
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Type (nagad_a1w_w_rtype)         :: df, p, x
      Real (Kind=nag_wp)               :: dfr, dxdf, dxdp, pr
      Integer                          :: i, ifail, n
      Character (1)                    :: tail
!     .. Executable Statements ..
      Write (nout,*) 'G01FB_A1W_F Example Program Results'

!     Create AD tape
      Call nagad_a1w_ir_create

!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      Write (nout,*)
      Write (nout,*) ' deviates and derivatives'
      Write (nout,*)
      Write (nout,*) ' tail   p            df           x            dx/dp' // &
        '       dx/ddf'

!     Create AD configuration data object
      ifail = 0
      Call x10aa_a1w_f(ad_handle,ifail)

      Do i = 1, n

        Read (nin,*) pr, dfr, tail
        p = pr
        df = dfr

!       Register variables to differentiate w.r.t.
        Call nagad_a1w_ir_register_variable(p)
        Call nagad_a1w_ir_register_variable(df)

        ifail = 0
        Call g01fb_a1w_f(ad_handle,tail,p,df,x,ifail)

        Call nagad_a1w_ir_zero_adjoints
        Call nagad_a1w_inc_derivative(x,1.0_nag_wp)
        ifail = 0
        Call nagad_a1w_ir_interpret_adjoint_sparse(ifail)

!       Get derivatives
        dxdp = nagad_a1w_get_derivative(p)
        dxdf = nagad_a1w_get_derivative(df)

        Write (nout,99999) tail, p%value, df%value, x%value, dxdp, dxdf
      End Do
99999 Format (1X,A5,1P,5E13.4)

!     Remove computational data object and tape
      Call x10ab_a1w_f(ad_handle,ifail)
      Call nagad_a1w_ir_remove

    End Program g01fb_a1w_fe