! F08PBF Example Program Text
! Mark 30.1 Release. NAG Copyright 2024.
Module f08pbfe_mod
! F08PBF Example Program Module:
! Parameters and User-defined Routines
! .. Use Statements ..
Use nag_library, Only: nag_wp
! .. Implicit None Statement ..
Implicit None
! .. Accessibility Statements ..
Private
Public :: select
! .. Parameters ..
Integer, Parameter, Public :: nb = 64, nin = 5, nout = 6
Logical, Parameter, Public :: check_fac = .True., &
print_cond = .False.
Contains
Function select(wr,wi)
! Logical function select for use with DGEESX (F08PBF)
! Returns the value .TRUE. if the eigenvalue is real and positive
! .. Function Return Value ..
Logical :: select
! .. Scalar Arguments ..
Real (Kind=nag_wp), Intent (In) :: wi, wr
! .. Executable Statements ..
select = (wr>0._nag_wp .And. wi==0._nag_wp)
Return
End Function select
End Module f08pbfe_mod
Program f08pbfe
! F08PBF Example Main Program
! .. Use Statements ..
Use f08pbfe_mod, Only: check_fac, nb, nin, nout, print_cond, select
Use nag_library, Only: dgeesx, dgemm, dlange => f06raf, nag_wp, x02ajf, &
x04caf
! .. Implicit None Statement ..
Implicit None
! .. Local Scalars ..
Real (Kind=nag_wp) :: alpha, anorm, beta, eps, norm, &
rconde, rcondv, tol
Integer :: i, ifail, info, lda, ldc, ldd, ldvs, &
liwork, lwork, n, sdim
! .. Local Arrays ..
Real (Kind=nag_wp), Allocatable :: a(:,:), c(:,:), d(:,:), vs(:,:), &
wi(:), work(:), wr(:)
Real (Kind=nag_wp) :: dummy(1)
Integer :: idum(1)
Integer, Allocatable :: iwork(:)
Logical, Allocatable :: bwork(:)
! .. Intrinsic Procedures ..
Intrinsic :: max, nint
! .. Executable Statements ..
Write (nout,*) 'F08PBF Example Program Results'
Write (nout,*)
Flush (nout)
! Skip heading in data file
Read (nin,*)
Read (nin,*) n
lda = n
ldc = n
ldd = n
ldvs = n
Allocate (a(lda,n),c(ldc,n),d(ldd,n),vs(ldvs,n),wi(n),wr(n),bwork(n))
! Use routine workspace query to get optimal workspace.
lwork = -1
liwork = -1
! The NAG name equivalent of dgeesx is f08pbf
Call dgeesx('Vectors (Schur)','Sort',select, &
'Both reciprocal condition numbers',n,a,lda,sdim,wr,wi,vs,ldvs,rconde, &
rcondv,dummy,lwork,idum,liwork,bwork,info)
! Make sure that there is enough workspace for block size nb.
liwork = max((n*n)/4,idum(1))
lwork = max(n*(nb+2+n/2),nint(dummy(1)))
Allocate (work(lwork),iwork(liwork))
! Read in the matrix A
Read (nin,*)(a(i,1:n),i=1,n)
! Copy A into D
d(1:n,1:n) = a(1:n,1:n)
! Print matrix A
! ifail: behaviour on error exit
! =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
ifail = 0
Call x04caf('General',' ',n,n,a,lda,'Matrix A',ifail)
Write (nout,*)
Flush (nout)
! Find the Frobenius norm of A
! The NAG name equivalent of the LAPACK auxiliary dlange is f06raf
anorm = dlange('Frobenius',n,n,a,lda,work)
! Find the Schur factorization of A
! The NAG name equivalent of dgeesx is f08pbf
Call dgeesx('Vectors (Schur)','Sort',select, &
'Both reciprocal condition numbers',n,a,lda,sdim,wr,wi,vs,ldvs,rconde, &
rcondv,work,lwork,iwork,liwork,bwork,info)
If (info/=0 .And. info/=(n+2)) Then
Write (nout,99993) 'Failure in DGEESX. INFO =', info
Go To 100
End If
If (check_fac) Then
! Compute A - Z*T*Z^T from the factorization of A and store in matrix D
! The NAG name equivalent of dgemm is f06yaf
alpha = 1.0_nag_wp
beta = 0.0_nag_wp
Call dgemm('N','N',n,n,n,alpha,vs,ldvs,a,lda,beta,c,ldc)
alpha = -1.0_nag_wp
beta = 1.0_nag_wp
Call dgemm('N','T',n,n,n,alpha,c,ldc,vs,ldvs,beta,d,ldd)
! Find norm of matrix D and print warning if it is too large
! f06raf is the NAG name equivalent of the LAPACK auxiliary dlange
norm = dlange('O',ldd,n,d,ldd,work)
If (norm>x02ajf()**0.8_nag_wp) Then
Write (nout,*) 'Norm of A-(Z*T*Z^T) is much greater than 0.'
Write (nout,*) 'Schur factorization has failed.'
Go To 100
End If
End If
! Print solution
Write (nout,99999) 'Number of eigenvalues for which SELECT is true = ', &
sdim, '(dimension of invariant subspace)'
Write (nout,*)
! Print eigenvalues.
Write (nout,*) 'Selected eigenvalues'
Write (nout,99998)(' (',wr(i),',',wi(i),')',i=1,sdim)
Write (nout,*)
If (info==(n+2)) Then
Write (nout,99997) '***Note that rounding errors mean ', &
'that leading eigenvalues in the Schur form', &
'no longer satisfy SELECT = .TRUE.'
Write (nout,*)
End If
Flush (nout)
If (print_cond) Then
! Print out the reciprocal condition numbers
Write (nout,99996) 'Reciprocal of projection norm onto the invariant', &
'subspace for the selected eigenvalues', 'RCONDE = ', rconde
Write (nout,*)
Write (nout,99995) &
'Reciprocal condition number for the invariant subspace', &
'RCONDV = ', rcondv
! Compute the machine precision
eps = x02ajf()
tol = eps*anorm
! Print out the approximate asymptotic error bound on the
! average absolute error of the selected eigenvalues given by
! eps*norm(A)/RCONDE
Write (nout,*)
Write (nout,99994) 'Approximate asymptotic error bound for selected ', &
'eigenvalues = ', tol/rconde
! Print out an approximate asymptotic bound on the maximum
! angular error in the computed invariant subspace given by
! eps*norm(A)/RCONDV
Write (nout,99994) &
'Approximate asymptotic error bound for the invariant ', &
'subspace = ', tol/rcondv
End If
100 Continue
99999 Format (1X,A,I4,/,1X,A)
99998 Format (1X,A,F8.4,A,F8.4,A)
99997 Format (1X,2A,/,1X,A)
99996 Format (1X,A,/,1X,A,/,1X,A,1P,E8.1)
99995 Format (1X,A,/,1X,A,1P,E8.1)
99994 Format (1X,2A,1P,E8.1)
99993 Format (1X,A,I4)
End Program f08pbfe