Program f08ctfe

!     F08CTF Example Program Text

!     Mark 30.1 Release. NAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: nag_wp, x04dbf, zgeqlf, zungql
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nb = 64, nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, ifail, info, lda, lwork, m, n
      Character (30)                   :: title
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: a(:,:), tau(:), work(:)
      Character (1)                    :: clabs(1), rlabs(1)
!     .. Executable Statements ..
      Write (nout,*) 'F08CTF Example Program Results'
      Write (nout,*)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) m, n
      lda = m
      lwork = nb*n
      Allocate (a(lda,n),tau(n),work(lwork))

!     Read A from data file

      Read (nin,*)(a(i,1:n),i=1,m)

!     Compute the QL factorization of A
!     The NAG name equivalent of zgeqlf is f08csf
      Call zgeqlf(m,n,a,lda,tau,work,lwork,info)

!     Form the leading N columns of Q explicitly
!     The NAG name equivalent of zungql is f08ctf
      Call zungql(m,n,n,a,lda,tau,work,lwork,info)

!     Form the heading for X04DBF

      Write (title,99999) n
      Flush (nout)

!     Print the leading N columns of Q

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call x04dbf('General',' ',m,n,a,lda,'Bracketed','F7.4',title,'Integer',  &
        rlabs,'Integer',clabs,80,0,ifail)

99999 Format ('The leading ',I4,' columns of Q')
    End Program f08ctfe