Program f07fufe

!     F07FUF Example Program Text

!     Mark 30.1 Release. NAG Copyright 2024.

!     .. Use Statements ..
      Use nag_library, Only: nag_wp, x02ajf, zlanhe => f06ucf, zpocon, zpotrf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: anorm, rcond
      Integer                          :: i, info, lda, n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: a(:,:), work(:)
      Real (Kind=nag_wp), Allocatable  :: rwork(:)
!     .. Executable Statements ..
      Write (nout,*) 'F07FUF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      lda = n
      Allocate (a(lda,n),work(2*n),rwork(n))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)(a(i,i:n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)(a(i,1:i),i=1,n)
      End If

!     Compute norm of A
!     f06ucf is the NAG name equivalent of the LAPACK auxiliary zlanhe
      anorm = zlanhe('1-norm',uplo,n,a,lda,rwork)

!     Factorize A
!     The NAG name equivalent of zpotrf is f07frf
      Call zpotrf(uplo,n,a,lda,info)

      Write (nout,*)
      If (info==0) Then

!       Estimate condition number
!       The NAG name equivalent of zpocon is f07fuf
        Call zpocon(uplo,n,a,lda,anorm,rcond,work,rwork,info)

        If (rcond>=x02ajf()) Then
          Write (nout,99999) 'Estimate of condition number =',                 &
            1.0E0_nag_wp/rcond
        Else
          Write (nout,*) 'A is singular to working precision'
        End If
      Else
        Write (nout,*) 'A is not positive definite'
      End If

99999 Format (1X,A,1P,E10.2)
    End Program f07fufe