Program f01fc_t1w_fe

!     F01FC_T1W_F Example Program Text
!     Mark 30.1 Release. NAG Copyright 2024.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: f01fc_t1w_f, nagad_t1w_set_derivative,          &
                               nagad_t1w_w_ctype, x10aa_t1w_f, x10ab_t1w_f,    &
                               Assignment (=)
      Use nag_library, Only: nag_wp, x04daf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Integer                          :: i, ierr, ifail, j, lda, n
!     .. Local Arrays ..
      Type (nagad_t1w_w_ctype), Allocatable :: a(:,:), a_in(:,:)
      Complex (Kind=nag_wp), Allocatable :: a_c(:,:)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: cmplx
!     .. Executable Statements ..
      Write (nout,*) 'F01FC_T1W_F Example Program Results'
      Write (nout,*)
      Flush (nout)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      lda = n
      Allocate (a(lda,n),a_in(lda,n),a_c(lda,n))

!     Read A from data file

      Read (nin,*)(a_c(i,1:n),i=1,n)

      a_in = a_c

!     Create AD configuration data object
      ifail = 0
      Call x10aa_t1w_f(ad_handle,ifail)

      Do i = 1, n
        Call nagad_t1w_set_derivative(a_in(i,i)%vimag,1.0_nag_wp)
        a = a_in

!       Find exp( A )
!         ifail: behaviour on error exit
!                =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call f01fc_t1w_f(ad_handle,n,a,lda,ifail)
        a_in(i,i)%vimag%tangent = 0.0_nag_wp

        If (i==1) Then
!         Print solution
          a_c = a
          ierr = 0
          Call x04daf('General',' ',n,n,a_c,lda,'Exp(A)',ierr)
        End If

        Do j = 1, n
          a_c(j,i) = cmplx(a(j,j)%vreal%tangent,a(j,j)%vimag%tangent,          &
            kind=nag_wp)
        End Do
      End Do

      Write (nout,*)
      Write (nout,*) ' Derivatives calculated: First order tangents'
      Write (nout,*) ' Computational mode    : algorithmic'

      Write (nout,*)
      Write (nout,*) ' Derivatives of diagonal of exp(A) w.r.t. diagonal of A'
      Write (nout,*)

      ierr = 0
      Call x04daf('General',' ',n,n,a_c,n,'   d(expA(i,i))/dimag(a(j,j))',     &
        ierr)

!     Remove computational data object
      Call x10ab_t1w_f(ad_handle,ifail)

    End Program f01fc_t1w_fe