! E04US_P0W_F Example Program Text
! Mark 29.0 Release. NAG Copyright 2023.
Module e04us_p0w_fe_mod
! E04US_P0W_F Example Program Module:
! Parameters and User-defined Routines
! .. Use Statements ..
Use iso_c_binding, Only: c_ptr
Use nag_library, Only: nag_wp
! .. Implicit None Statement ..
Implicit None
! .. Accessibility Statements ..
Private
Public :: confun, objfun
! .. Parameters ..
Integer, Parameter, Public :: nin = 5, nout = 6
Contains
Subroutine objfun(ad_handle,mode,m,n,ldfj,needfi,x,f,fjac,nstate,iuser, &
ruser)
! .. Scalar Arguments ..
Type (c_ptr), Intent (Inout) :: ad_handle
Integer, Intent (In) :: ldfj, m, n, needfi, nstate
Integer, Intent (Inout) :: mode
! .. Array Arguments ..
Real (Kind=nag_wp), Intent (Out) :: f(m)
Real (Kind=nag_wp), Intent (Inout) :: fjac(ldfj,n), ruser(*)
Real (Kind=nag_wp), Intent (In) :: x(n)
Integer, Intent (Inout) :: iuser(*)
! .. Local Scalars ..
Real (Kind=nag_wp) :: ai, temp, x1, x2
Integer :: i
Logical :: mode02, mode12
! .. Intrinsic Procedures ..
Intrinsic :: exp
! .. Executable Statements ..
x1 = x(1)
x2 = x(2)
If (mode==0 .And. needfi>0) Then
f(needfi) = x1 + (0.49_nag_wp-x1)*exp(-x2*(ruser(needfi)-8.0_nag_wp) &
)
Else
mode02 = (mode==0 .Or. mode==2)
mode12 = (mode==1 .Or. mode==2)
Do i = 1, m
ai = ruser(i) - 8.0_nag_wp
temp = exp(-x2*ai)
If (mode02) Then
f(i) = x1 + (0.49_nag_wp-x1)*temp
End If
If (mode12) Then
fjac(i,1) = 1.0_nag_wp - temp
fjac(i,2) = -(0.49_nag_wp-x1)*ai*temp
End If
End Do
End If
Return
End Subroutine objfun
Subroutine confun(ad_handle,mode,ncnln,n,ldcj,needc,x,c,cjac,nstate, &
iuser,ruser)
! Routine to evaluate the nonlinear constraint and jacobian
! .. Scalar Arguments ..
Type (c_ptr), Intent (Inout) :: ad_handle
Integer, Intent (In) :: ldcj, n, ncnln, nstate
Integer, Intent (Inout) :: mode
! .. Array Arguments ..
Real (Kind=nag_wp), Intent (Out) :: c(ncnln)
Real (Kind=nag_wp), Intent (Inout) :: cjac(ldcj,n), ruser(*)
Real (Kind=nag_wp), Intent (In) :: x(n)
Integer, Intent (Inout) :: iuser(*)
Integer, Intent (In) :: needc(ncnln)
! .. Executable Statements ..
If (nstate==1) Then
! First call to CONFUN. Set all Jacobian elements to zero.
! Note that this will only work when 'Derivative Level = 3'
! (the default; see Section 11.2).
cjac(1:ncnln,1:n) = 0.0_nag_wp
End If
If (needc(1)>0) Then
If (mode==0 .Or. mode==2) Then
c(1) = -0.09_nag_wp - x(1)*x(2) + 0.49_nag_wp*x(2)
End If
If (mode==1 .Or. mode==2) Then
cjac(1,1) = -x(2)
cjac(1,2) = -x(1) + 0.49_nag_wp
End If
End If
Return
End Subroutine confun
End Module e04us_p0w_fe_mod
Program e04us_p0w_fe
! E04US_P0W_F Example Main Program
! .. Use Statements ..
Use e04us_p0w_fe_mod, Only: confun, nin, nout, objfun
Use iso_c_binding, Only: c_ptr
Use nagad_library, Only: e04ur_p0w_f, e04us_p0w_f, e04wb_p0w_f
Use nag_library, Only: nag_wp, x04caf
! .. Implicit None Statement ..
Implicit None
! .. Local Scalars ..
Type (c_ptr) :: ad_handle
Real (Kind=nag_wp) :: objf
Integer :: i, ifail, inform, iter, lb, lda, &
ldcj, ldfj, ldr, liwork, lwork, m, &
n, nclin, ncnln, sda
! .. Local Arrays ..
Real (Kind=nag_wp), Allocatable :: a(:,:), bl(:), bu(:), c(:), &
cjac(:,:), clamda(:), f(:), &
fjac(:,:), r(:,:), rwsav(:), &
work(:), x(:), y(:)
Real (Kind=nag_wp) :: ruser(44)
Integer, Allocatable :: istate(:), iwork(:), iwsav(:)
Integer :: iuser(1)
Logical, Allocatable :: lwsav(:)
Character (80) :: cwsav(1)
! .. Intrinsic Procedures ..
Intrinsic :: max
! .. Executable Statements ..
Write (nout,*) 'E04US_P0W_F Example Program Results'
! Skip heading in data file
Read (nin,*)
! Read the computational mode: 1 = algorithmic, 2 = symbolic
Read (nin,*) m, n
Read (nin,*) nclin, ncnln
liwork = 3*n + nclin + 2*ncnln
lda = max(1,nclin)
If (nclin>0) Then
sda = n
Else
sda = 1
End If
ldcj = max(1,ncnln)
ldfj = m
ldr = n
If (ncnln==0 .And. nclin>0) Then
lwork = 2*n**2 + 20*n + 11*nclin + m*(n+3)
Else If (ncnln>0 .And. nclin>=0) Then
lwork = 2*n**2 + n*nclin + 2*n*ncnln + 20*n + 11*nclin + 21*ncnln + &
m*(n+3)
Else
lwork = 20*n + m*(n+3)
End If
lb = n + nclin + ncnln
Allocate (istate(lb),iwork(liwork),a(lda,sda),bl(lb),bu(lb),y(m), &
c(ncnln),cjac(ncnln,n),f(m),fjac(m,n),clamda(lb),r(ldr,n),x(n), &
work(lwork),lwsav(120),iwsav(610),rwsav(475))
If (nclin>0) Then
Read (nin,*)(a(i,1:sda),i=1,nclin)
End If
Read (nin,*) y(1:m)
Read (nin,*) bl(1:lb)
Read (nin,*) bu(1:lb)
Read (nin,*) x(1:n)
ruser(1:44) = (/8.0E0_nag_wp,8.0E0_nag_wp,10.0E0_nag_wp,10.0E0_nag_wp, &
10.0E0_nag_wp,10.0E0_nag_wp,12.0E0_nag_wp,12.0E0_nag_wp,12.0E0_nag_wp, &
12.0E0_nag_wp,14.0E0_nag_wp,14.0E0_nag_wp,14.0E0_nag_wp,16.0E0_nag_wp, &
16.0E0_nag_wp,16.0E0_nag_wp,18.0E0_nag_wp,18.0E0_nag_wp,20.0E0_nag_wp, &
20.0E0_nag_wp,20.0E0_nag_wp,22.0E0_nag_wp,22.0E0_nag_wp,22.0E0_nag_wp, &
24.0E0_nag_wp,24.0E0_nag_wp,24.0E0_nag_wp,26.0E0_nag_wp,26.0E0_nag_wp, &
26.0E0_nag_wp,28.0E0_nag_wp,28.0E0_nag_wp,30.0E0_nag_wp,30.0E0_nag_wp, &
30.0E0_nag_wp,32.0E0_nag_wp,32.0E0_nag_wp,34.0E0_nag_wp,36.0E0_nag_wp, &
36.0E0_nag_wp,38.0E0_nag_wp,38.0E0_nag_wp,40.0E0_nag_wp, &
42.0E0_nag_wp/)
! Initialize sav arrays
ifail = 0
Call e04wb_p0w_f('E04USA',cwsav,1,lwsav,120,iwsav,610,rwsav,475,ifail)
! Set option via string
Call e04ur_p0w_f('Print Level = 1',lwsav,iwsav,rwsav,inform)
! Solve the problem
ifail = 0
Call e04us_p0w_f(ad_handle,m,n,nclin,ncnln,lda,ldcj,ldfj,ldr,a,bl,bu,y, &
confun,objfun,iter,istate,c,cjac,f,fjac,clamda,objf,r,x,iwork,liwork, &
work,lwork,iuser,ruser,lwsav,iwsav,rwsav,ifail)
Write (nout,99999) ' Optimal solution = ', objf
99999 Format (1X,A,F10.5)
Write (nout,*)
Call x04caf('General',' ',1,n,x,1,' Solution point, x',ifail)
End Program e04us_p0w_fe