Program c06rafe

!     C06RAF Example Program Text

!     Mark 29.0 Release. NAG Copyright 2023.

!     .. Use Statements ..
      Use nag_library, Only: c06raf, nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, ieof, ifail, j, m, n
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: work(:), x(:)
!     .. Executable Statements ..
      Write (nout,*) 'C06RAF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
loop: Do
        Read (nin,*,Iostat=ieof) m, n
        If (ieof<0) Then
          Exit loop
        End If

        Allocate (x(m*(n+2)),work(m*n+2*n+2*m+15))
        Do j = 1, m
          Read (nin,*)(x((i-1)*m+j),i=1,n-1)
        End Do
        Write (nout,*)
        Write (nout,*) 'Original data values'
        Write (nout,*)
        Do j = 1, m
          Write (nout,99999)(x((i-1)*m+j),i=1,n-1)
        End Do

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
!       -- Compute transform
        Call c06raf(m,n,x,work,ifail)

        Write (nout,*)
        Write (nout,*) 'Discrete Fourier sine transforms'
        Write (nout,*)
        Do j = 1, m
          Write (nout,99999)(x((i-1)*m+j),i=1,n-1)
        End Do

!       -- Compute inverse transform
        Call c06raf(m,n,x,work,ifail)

        Write (nout,*)
        Write (nout,*) 'Original data as restored by inverse transform'
        Write (nout,*)
        Do j = 1, m
          Write (nout,99999)(x((i-1)*m+j),i=1,n-1)
        End Do
        Deallocate (x,work)
      End Do loop

99999 Format (6X,6F10.4)
    End Program c06rafe