Program e01bg_a1w_fe

!     E01BG_A1W_F Example Program Text
!     Mark 29.3 Release. NAG Copyright 2023.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: e01be_a1w_f, e01bg_a1w_f,                       &
                               nagad_a1w_get_derivative,                       &
                               nagad_a1w_inc_derivative,                       &
                               nagad_a1w_ir_create => x10za_a1w_f,             &
                               nagad_a1w_ir_interpret_adjoint_sparse,          &
                               nagad_a1w_ir_register_variable,                 &
                               nagad_a1w_ir_remove, nagad_a1w_w_rtype,         &
                               x10aa_a1w_f, x10ab_a1w_f, Assignment (=)
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Real (Kind=nag_wp)               :: fr, xr
      Integer                          :: i, ifail, m, n, r
!     .. Local Arrays ..
      Type (nagad_a1w_w_rtype), Allocatable :: d(:), f(:), pd(:), pf(:),       &
                                          px(:), x(:)
      Real (Kind=nag_wp), Allocatable  :: df(:), dx(:)
!     .. Executable Statements ..

      Write (nout,*) 'E01BG_A1W_F Example Program Results'

!     Skip heading in data file
      Read (nin,*)

      Read (nin,*) n
      m = 1
      Allocate (d(n),f(n),x(n),dx(n),df(n),px(m),pf(m),pd(m))

!     Create AD tape
      Call nagad_a1w_ir_create

!     Initialize x and f arrays using data
      Do r = 1, n
        Read (nin,*) xr, fr
        x(r) = xr
        f(r) = fr
      End Do

!     Create AD configuration data object
      ifail = 0
      Call x10aa_a1w_f(ad_handle,ifail)

!     Register variables to differentiate w.r.t.
      Call nagad_a1w_ir_register_variable(x)
      Call nagad_a1w_ir_register_variable(f)

!     Call the AD routine
      ifail = 0
      Call e01be_a1w_f(ad_handle,n,x,f,d,ifail)

!     Evaluate interpolant and derivatives at a mid-point
      px(1) = 0.5_nag_wp*(x(n/2)%value+x(n/2+1)%value)
      Call e01bg_a1w_f(ad_handle,n,x,f,d,m,px,pf,pd,ifail)

      Write (nout,*)
      Write (nout,*) ' Derivatives calculated: First order adjoints'
      Write (nout,*) ' Computational mode    : algorithmic'


!     Get derivative of interpolated value w.r.t data points and values
      Call nagad_a1w_inc_derivative(pf(1),1.0_nag_wp)
      Call nagad_a1w_ir_interpret_adjoint_sparse(ifail)

      dx(1:n) = nagad_a1w_get_derivative(x)
      df(1:n) = nagad_a1w_get_derivative(f)

      Write (nout,*)
      Write (nout,99999) 'Interpolated value at x = ', px(1)%value, ' is: ',   &
        pf(1)%value
99999 Format (1X,A,F7.3,A,E12.5)
      Write (nout,*)
      Write (nout,*) ' Derivatives of interpolated value w.r.t. x and f:'
      Write (nout,*)
      Write (nout,*) '    i      d/dx         d/df'
      Do i = 1, n
        Write (nout,99998) i, dx(i), df(i)
      End Do
99998 Format (1X,I5,1X,E12.5,1X,E12.5)

!     Remove computational data object and tape
      ifail = 0
      Call x10ab_a1w_f(ad_handle,ifail)
      Call nagad_a1w_ir_remove

    End Program e01bg_a1w_fe