Program f08uefe

!     F08UEF Example Program Text

!     Mark 29.1 Release. NAG Copyright 2023.

!     .. Use Statements ..
      Use nag_library, Only: dpbstf, dsbgst, dsbtrd, dsterf, nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, info, j, ka, kb, ldab, ldbb, ldx, &
                                          n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: ab(:,:), bb(:,:), d(:), e(:),        &
                                          work(:), x(:,:)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: max, min
!     .. Executable Statements ..
      Write (nout,*) 'F08UEF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n, ka, kb
      ldab = ka + 1
      ldbb = kb + 1
      ldx = n
      Allocate (ab(ldab,n),bb(ldbb,n),d(n),e(n-1),work(2*n),x(ldx,n))

!     Read A and B from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Do i = 1, n
          Read (nin,*)(ab(ka+1+i-j,j),j=i,min(n,i+ka))
        End Do
        Do i = 1, n
          Read (nin,*)(bb(kb+1+i-j,j),j=i,min(n,i+kb))
        End Do
      Else If (uplo=='L') Then
        Do i = 1, n
          Read (nin,*)(ab(1+i-j,j),j=max(1,i-ka),i)
        End Do
        Do i = 1, n
          Read (nin,*)(bb(1+i-j,j),j=max(1,i-kb),i)
        End Do
      End If

!     Compute the split Cholesky factorization of B
!     The NAG name equivalent of dpbstf is f08uff
      Call dpbstf(uplo,n,kb,bb,ldbb,info)

      Write (nout,*)
      If (info>0) Then
        Write (nout,*) 'B is not positive definite.'
      Else

!       Reduce the problem to standard form C*y = lambda*y, storing
!       the result in A
!       The NAG name equivalent of dsbgst is f08uef
        Call dsbgst('N',uplo,n,ka,kb,ab,ldab,bb,ldbb,x,ldx,work,info)

!       Reduce C to tridiagonal form T = (Q**T)*C*Q
!       The NAG name equivalent of dsbtrd is f08hef
        Call dsbtrd('N',uplo,n,ka,ab,ldab,d,e,x,ldx,work,info)

!       Calculate the eigenvalues of T (same as C)
!       The NAG name equivalent of dsterf is f08jff
        Call dsterf(n,d,e,info)

        If (info>0) Then
          Write (nout,*) 'Failure to converge.'
        Else

!         Print eigenvalues

          Write (nout,*) 'Eigenvalues'
          Write (nout,99999) d(1:n)
        End If
      End If

99999 Format (3X,(8F8.4))
    End Program f08uefe