!   D01FB_T1W_F Example Program Text
!   Mark 29.1 Release. NAG Copyright 2023.

    Module d01fb_t1w_fe_mod

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: exp, nagad_t1w_w_rtype, Operator (/),           &
                               Operator (**), Operator (+), Operator (-),      &
                               Operator (*)
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Accessibility Statements ..
      Private
      Public                           :: fun
!     .. Parameters ..
      Integer, Parameter, Public       :: ndim = 4, nout = 6
    Contains
      Subroutine fun(ad_handle,ndim,x,ret,iuser,ruser)

!       .. Scalar Arguments ..
        Type (c_ptr), Intent (Inout)   :: ad_handle
        Type (nagad_t1w_w_rtype), Intent (Out) :: ret
        Integer, Intent (In)           :: ndim
!       .. Array Arguments ..
        Type (nagad_t1w_w_rtype), Intent (Inout) :: ruser(*)
        Type (nagad_t1w_w_rtype), Intent (In) :: x(ndim)
        Integer, Intent (Inout)        :: iuser(*)
!       .. Executable Statements ..
        ret = (x(1)*x(2)*x(3))**6/(x(4)+2.0E0_nag_wp)**8*                      &
          exp(-2.0_nag_wp*x(2)-0.5_nag_wp*x(3)*x(3))
        Return

      End Subroutine fun
    End Module d01fb_t1w_fe_mod

    Program d01fb_t1w_fe
!     D01FB_T1W_F Example Main Program

!     .. Use Statements ..
      Use d01fb_t1w_fe_mod, Only: fun, ndim, nout
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: d01fb_t1w_f, nagad_t1w_w_rtype, x10aa_t1w_f,    &
                               x10ab_t1w_f, Assignment (=)
      Use nag_library, Only: d01tbf, nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Type (nagad_t1w_w_rtype)         :: ans
      Real (Kind=nag_wp)               :: a, b
      Integer                          :: i, ifail, j, k, lwa
!     .. Local Arrays ..
      Type (nagad_t1w_w_rtype), Allocatable :: abscis_t1w(:), weight_t1w(:)
      Type (nagad_t1w_w_rtype)         :: ruser(1)
      Real (Kind=nag_wp), Allocatable  :: abscis(:), weight(:)
      Integer                          :: iuser(1), nptvec(ndim)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: sum
!     .. Executable Statements ..

      Write (nout,*) 'D01FB_T1W_F Example Program Results'

      nptvec(1:ndim) = (/4,4,4,4/)
      lwa = sum(nptvec(1:ndim))

      Allocate (abscis(lwa),weight(lwa),abscis_t1w(lwa),weight_t1w(lwa))
      j = 1

!     Evaluate primal weights and abscisae in each dimension
      Do i = 1, 4
        ifail = 0
        Select Case (i)
        Case (1)
          a = 1.0E0_nag_wp
          b = 2.0E0_nag_wp
          Call d01tbf(0,a,b,nptvec(i),weight(j),abscis(j),ifail)
        Case (2)
          a = 0.0E0_nag_wp
          b = 2.0E0_nag_wp
          Call d01tbf(-3,a,b,nptvec(i),weight(j),abscis(j),ifail)
        Case (3)
          a = 0.0E0_nag_wp
          b = 0.5E0_nag_wp
          Call d01tbf(-4,a,b,nptvec(i),weight(j),abscis(j),ifail)
        Case (4)
          a = 1.0E0_nag_wp
          b = 2.0E0_nag_wp
          Call d01tbf(-5,a,b,nptvec(i),weight(j),abscis(j),ifail)
        End Select

        j = j + nptvec(i)
      End Do

!     Create AD configuration data object
      ifail = 0
      Call x10aa_t1w_f(ad_handle,ifail)

      weight_t1w(1:lwa) = weight(1:lwa)
      abscis_t1w(1:lwa) = abscis(1:lwa)

!     Get primal solution
      ifail = 0
      Call d01fb_t1w_f(ad_handle,ndim,nptvec,lwa,weight_t1w,abscis_t1w,fun,    &
        ans,iuser,ruser,ifail)
      Write (nout,*)
      Write (nout,99999) ' Solution, x =', ans%value

      Write (nout,*)
      Write (nout,*) ' Derivatives calculated: First order tangents'
      Write (nout,*) ' Computational mode    : algorithmic'

      Write (nout,*) ' Derivatives:'
      Write (nout,*) ' dim  j   da/dweight   da/dabscis'
      j = 0
      Do i = 1, 4
        Do k = 1, nptvec(i)
          j = j + 1

!         Call the AD routine for derivative s.r.t. weight and abscissa
          weight_t1w(j)%tangent = 1.0_nag_wp
          ifail = 0
          Call d01fb_t1w_f(ad_handle,ndim,nptvec,lwa,weight_t1w,abscis_t1w,    &
            fun,ans,iuser,ruser,ifail)
          weight(j) = ans%tangent
          weight_t1w(j)%tangent = 0.0_nag_wp

          abscis_t1w(j)%tangent = 1.0_nag_wp
          ifail = 0
          Call d01fb_t1w_f(ad_handle,ndim,nptvec,lwa,weight_t1w,abscis_t1w,    &
            fun,ans,iuser,ruser,ifail)
          abscis(j) = ans%tangent
          abscis_t1w(j)%tangent = 0.0_nag_wp

          If (k==1) Then
            Write (nout,99998) i, 1, weight(j), abscis(j)
          Else
            Write (nout,99997) k, weight(j), abscis(j)
          End If
        End Do
      End Do
99999 Format (1X,A,1X,F12.5)
99998 Format (1X,I3,1X,I3,1X,E12.5,1X,E12.5)
99997 Format (6X,I2,1X,E12.5,1X,E12.5)

!     Remove computational data object
      ifail = 0
      Call x10ab_t1w_f(ad_handle,ifail)

    End Program d01fb_t1w_fe