!   D01FB_P0W_F Example Program Text
!   Mark 29.1 Release. NAG Copyright 2023.

    Module d01fb_p0w_fe_mod

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Accessibility Statements ..
      Private
      Public                           :: fun
!     .. Parameters ..
      Integer, Parameter, Public       :: ndim = 4, nout = 6
    Contains
      Subroutine fun(ad_handle,ndim,x,ret,iuser,ruser)

!       .. Scalar Arguments ..
        Type (c_ptr), Intent (Inout)   :: ad_handle
        Real (Kind=nag_wp), Intent (Out) :: ret
        Integer, Intent (In)           :: ndim
!       .. Array Arguments ..
        Real (Kind=nag_wp), Intent (Inout) :: ruser(*)
        Real (Kind=nag_wp), Intent (In) :: x(ndim)
        Integer, Intent (Inout)        :: iuser(*)
!       .. Intrinsic Procedures ..
        Intrinsic                      :: exp
!       .. Executable Statements ..
        ret = (x(1)*x(2)*x(3))**6/(x(4)+2.0E0_nag_wp)**8*                      &
          exp(-2.0_nag_wp*x(2)-0.5_nag_wp*x(3)*x(3))
        Return

      End Subroutine fun
    End Module d01fb_p0w_fe_mod

    Program d01fb_p0w_fe
!     D01FB_P0W_F Example Main Program

!     .. Use Statements ..
      Use d01fb_p0w_fe_mod, Only: fun, ndim, nout
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: d01fb_p0w_f
      Use nag_library, Only: d01tbf, nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Real (Kind=nag_wp)               :: a, ans, b
      Integer                          :: i, ifail, j, lwa
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: abscis(:), weight(:)
      Real (Kind=nag_wp)               :: ruser(1)
      Integer                          :: iuser(1), nptvec(ndim)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: sum
!     .. Executable Statements ..

      Write (nout,*) 'D01FB_P0W_F Example Program Results'

      nptvec(1:ndim) = (/4,4,4,4/)
      lwa = sum(nptvec(1:ndim))

      Allocate (abscis(lwa),weight(lwa))
      j = 1

!     Evaluate primal weights and abscisae in each dimension
      Do i = 1, 4
        ifail = 0
        Select Case (i)
        Case (1)
          a = 1.0E0_nag_wp
          b = 2.0E0_nag_wp
          Call d01tbf(0,a,b,nptvec(i),weight(j),abscis(j),ifail)
        Case (2)
          a = 0.0E0_nag_wp
          b = 2.0E0_nag_wp
          Call d01tbf(-3,a,b,nptvec(i),weight(j),abscis(j),ifail)
        Case (3)
          a = 0.0E0_nag_wp
          b = 0.5E0_nag_wp
          Call d01tbf(-4,a,b,nptvec(i),weight(j),abscis(j),ifail)
        Case (4)
          a = 1.0E0_nag_wp
          b = 2.0E0_nag_wp
          Call d01tbf(-5,a,b,nptvec(i),weight(j),abscis(j),ifail)
        End Select

        j = j + nptvec(i)
      End Do

!     Call the passive routine
      ifail = 0
      Call d01fb_p0w_f(ad_handle,ndim,nptvec,lwa,weight,abscis,fun,ans,iuser,  &
        ruser,ifail)

      Write (nout,*)
      Write (nout,99999) ' Solution, x =', ans

99999 Format (1X,A,1X,F12.5)

    End Program d01fb_p0w_fe