Program g01fe_a1w_fe

!     G01FE_A1W_F Example Program Text
!     Mark 28.6 Release. NAG Copyright 2022.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: g01fe_a1w_f, nagad_a1w_get_derivative,          &
                               nagad_a1w_inc_derivative,                       &
                               nagad_a1w_ir_create => x10za_a1w_f,             &
                               nagad_a1w_ir_interpret_adjoint_sparse,          &
                               nagad_a1w_ir_register_variable,                 &
                               nagad_a1w_ir_remove, nagad_a1w_ir_zero_adjoints &
                               , nagad_a1w_w_rtype, x10aa_a1w_f, x10ab_a1w_f,  &
                               Assignment (=)
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (nagad_a1w_w_rtype)         :: a, b, p, tol, x
      Type (c_ptr)                     :: ad_handle
      Real (Kind=nag_wp)               :: ar, br, dxda, dxdb, dxdp, pr
      Integer                          :: i, ifail, n
!     .. Executable Statements ..
      Write (nout,*) 'G01FE_A1W_F Example Program Results'

!     Create AD tape
      Call nagad_a1w_ir_create

!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      tol = 0.0_nag_wp

      Write (nout,*)
      Write (nout,*) ' deviates and derivatives'
      Write (nout,*)
      Write (nout,99998) 'p', 'a', 'b', 'x', 'dx/dp', 'dx/da', 'dx/db'

!     Create AD configuration data object
      ifail = 0
      Call x10aa_a1w_f(ad_handle,ifail)

      Do i = 1, n

        Read (nin,*) pr, ar, br
        p = pr
        a = ar
        b = br

!       Register variables to differentiate w.r.t.
        Call nagad_a1w_ir_register_variable(p)
        Call nagad_a1w_ir_register_variable(a)
        Call nagad_a1w_ir_register_variable(b)

        ifail = 0
        Call g01fe_a1w_f(ad_handle,p,a,b,tol,x,ifail)

        Call nagad_a1w_ir_zero_adjoints
        Call nagad_a1w_inc_derivative(x,1.0_nag_wp)
        ifail = 0
        Call nagad_a1w_ir_interpret_adjoint_sparse(ifail)

!       Get derivatives
        dxdp = nagad_a1w_get_derivative(p)
        dxda = nagad_a1w_get_derivative(a)
        dxdb = nagad_a1w_get_derivative(b)

        Write (nout,99999) p%value, a%value, b%value, x%value, dxdp, dxda,     &
          dxdb
      End Do
99999 Format (1X,1P,7E11.2)
99998 Format (1X,A4,3A11,A15,2A11)

!     Remove computational data object and tape
      Call x10ab_a1w_f(ad_handle,ifail)
      Call nagad_a1w_ir_remove

    End Program g01fe_a1w_fe