Program f11dpfe

!     F11DPF Example Program Text

!     Mark 28.6 Release. NAG Copyright 2022.

!     .. Use Statements ..
      Use nag_library, Only: f11dnf, f11dpf, nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: dtol
      Integer                          :: i, ifail, la, lfill, liwork, n, nnz, &
                                          nnzc, npivm
      Character (1)                    :: check, milu, pstrat, trans
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: a(:), x(:), y(:)
      Integer, Allocatable             :: icol(:), idiag(:), ipivp(:),         &
                                          ipivq(:), irow(:), istr(:), iwork(:)
!     .. Executable Statements ..
      Write (nout,*) 'F11DPF Example Program Results'
      Write (nout,*)
!     Skip heading in data file
      Read (nin,*)

!     Read order of matrix and number of nonzero entries

      Read (nin,*) n
      Read (nin,*) nnz
      la = 3*nnz
      liwork = 7*n + 2
      Allocate (a(la),x(n),y(n),icol(la),idiag(n),ipivp(n),ipivq(n),irow(la),  &
        istr(n+1),iwork(liwork))

!     Read the matrix A

      Do i = 1, nnz
        Read (nin,*) a(i), irow(i), icol(i)
      End Do

!     Read the vector y

      Read (nin,*) y(1:n)

!     Calculate LU factorization

      lfill = -1
      dtol = 0.0E0_nag_wp
      pstrat = 'C'
      milu = 'N'

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call f11dnf(n,nnz,a,la,irow,icol,lfill,dtol,pstrat,milu,ipivp,ipivq,     &
        istr,idiag,nnzc,npivm,iwork,liwork,ifail)

!     Check value of NPIVM

      If (npivm>0) Then

        Write (nout,*) 'Factorization is not complete'

      Else

!       Solve P L D U x = y

        trans = 'N'
        check = 'C'

        ifail = 0
        Call f11dpf(trans,n,a,la,irow,icol,ipivp,ipivq,istr,idiag,check,y,x,   &
          ifail)

!       Output results

        Write (nout,*) 'Solution of linear system'
        Write (nout,99999) x(1:n)
      End If

99999 Format (1X,'(',E16.4,',',E16.4,')')
    End Program f11dpfe