Program f11db_a1w_fe

!     F11DB_A1W_F Example Program Text

!     Mark 28.5 Release. NAG Copyright 2022.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: f11da_a1w_f, f11db_a1w_f,                       &
                               nagad_a1w_get_derivative,                       &
                               nagad_a1w_inc_derivative,                       &
                               nagad_a1w_ir_interpret_adjoint_sparse,          &
                               nagad_a1w_ir_register_variable,                 &
                               nagad_a1w_ir_remove, nagad_a1w_ir_zero_adjoints &
                               , nagad_a1w_w_rtype, x10aa_a1w_f, x10ab_a1w_f,  &
                               x10za_a1w_f, Assignment (=)
      Use nag_library, Only: nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Type (nagad_a1w_w_rtype)         :: dtol
      Integer                          :: i, ifail, j, la, lfill, liwork, n,   &
                                          nnz, nnzc, npivm
      Character (1)                    :: check, milu, pstrat, trans
!     .. Local Arrays ..
      Type (nagad_a1w_w_rtype), Allocatable :: a(:), x(:), y(:)
      Real (Kind=nag_wp), Allocatable  :: ar(:), dxdy(:,:), xr(:), yr(:)
      Integer, Allocatable             :: icol(:), idiag(:), ipivp(:),         &
                                          ipivq(:), irow(:), istr(:), iwork(:)
!     .. Executable Statements ..
      Write (nout,*) 'F11DB_A1W_F Example Program Results'
      Write (nout,*)

!     Skip heading in data file

      Read (nin,*)

!     Read order of matrix and number of nonzero entries

      Read (nin,*) n
      Read (nin,*) nnz
      la = 2*nnz
      liwork = 7*n + 2
      Allocate (a(la),x(n),y(n),icol(la),idiag(n),ipivp(n),ipivq(n),irow(la),  &
        istr(n+1),iwork(liwork))
      Allocate (ar(la),xr(n),yr(n),dxdy(n,n))

!     Read the matrix A

      Do i = 1, nnz
        Read (nin,*) ar(i), irow(i), icol(i)
      End Do
      a = ar

!     Read the vector y

      Read (nin,*) yr(1:n)
      y = yr

!     Create AD tape
      Call x10za_a1w_f

!     Create AD configuration data object
      ifail = 0
      Call x10aa_a1w_f(ad_handle,ifail)

!     Register variables to differentiate w.r.t.
      Call nagad_a1w_ir_register_variable(y)

!     Calculate LU factorization

      lfill = -1
      dtol = 0.E0_nag_wp
      pstrat = 'C'
      milu = 'N'

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call f11da_a1w_f(ad_handle,n,nnz,a,la,irow,icol,lfill,dtol,pstrat,milu,  &
        ipivp,ipivq,istr,idiag,nnzc,npivm,iwork,liwork,ifail)

!     Check value of npivm

      If (npivm>0) Then

        Write (nout,*) 'Factorization is not complete'

      Else

!       Solve P L D U x = y

        trans = 'N'
        check = 'C'

        ifail = 0
        Call f11db_a1w_f(ad_handle,trans,n,a,la,irow,icol,ipivp,ipivq,istr,    &
          idiag,check,y,x,ifail)

!       Output results

        Write (nout,*) ' Solution of linear system'
        Write (nout,'(E16.4)') x(1:n)%value

        Write (nout,*)
        Write (nout,*) ' Derivatives calculated: First order adjoints'
        Write (nout,*) ' Computational mode    : algorithmic'

        Write (nout,*)
        Write (nout,*) ' Derivatives of solution X w.r.t. RHS B (A inverse)'
        Write (nout,*)
!       Setup evaluation of derivatives via adjoints
        Do i = 1, n
          Call nagad_a1w_ir_zero_adjoints
          Call nagad_a1w_inc_derivative(x(i),1.0_nag_wp)
          ifail = 0
          Call nagad_a1w_ir_interpret_adjoint_sparse(ifail)

!         Get derivatives
          Do j = 1, n
            dxdy(i,j) = nagad_a1w_get_derivative(y(j))
          End Do
        End Do
        Call x04caf('General',' ',n,n,dxdy,n,'       dx(i)/dy(j)',ifail)
      End If

!     Remove computational data object and tape
      Call x10ab_a1w_f(ad_handle,ifail)
      Call nagad_a1w_ir_remove

    End Program f11db_a1w_fe