Program f08cjfe

!     F08CJF Example Program Text

!     Mark 28.5 Release. NAG Copyright 2022.

!     .. Use Statements ..
      Use nag_library, Only: dgerqf, dorgrq, nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nb = 64, nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, ifail, info, lda, lwork, m, n
      Character (26)                   :: title
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: a(:,:), tau(:), work(:)
!     .. Executable Statements ..
      Write (nout,*) 'F08CJF Example Program Results'
      Write (nout,*)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) m, n
      lda = m
      lwork = nb*m
      Allocate (a(lda,n),tau(n),work(lwork))

!     Read A from data file

      Read (nin,*)(a(i,1:n),i=1,m)

!     Compute the RQ factorization of A
!     The NAG name equivalent of dgerqf is f08chf
      Call dgerqf(m,n,a,lda,tau,work,lwork,info)

!     Form the leading M rows of Q explicitly
!     The NAG name equivalent of dorgrq is f08cjf
      Call dorgrq(m,n,m,a,lda,tau,work,lwork,info)

!     Form the heading for X04CAF

      Write (title,99999) m
      Flush (nout)

!     Print the leading M rows of Q

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0
      Call x04caf('General',' ',m,n,a,lda,title,ifail)

99999 Format ('The leading ',I4,' rows of Q')
    End Program f08cjfe