Program f08vsfe

!     F08VSF Example Program Text

!     Mark 28.4 Release. NAG Copyright 2022.

!     .. Use Statements ..
      Use nag_library, Only: f06uaf, nag_wp, x02ajf, x04dbf, zggsvp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: eps, tola, tolb
      Integer                          :: i, ifail, info, irank, k, l, lda,    &
                                          ldb, ldq, ldu, ldv, m, n, p
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: a(:,:), b(:,:), q(:,:), tau(:),    &
                                          u(:,:), v(:,:), work(:)
      Real (Kind=nag_wp), Allocatable  :: rwork(:)
      Integer, Allocatable             :: iwork(:)
      Character (1)                    :: clabs(1), rlabs(1)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: max, real
!     .. Executable Statements ..
      Write (nout,*) 'F08VSF Example Program Results'
      Write (nout,*)
      Flush (nout)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) m, n, p
      lda = m
      ldb = p
      ldq = n
      ldu = m
      ldv = p
      Allocate (a(lda,n),b(ldb,n),q(ldq,n),tau(n),u(ldu,m),v(ldv,p),           &
        work(m+3*n+p),rwork(2*n),iwork(n))

!     Read the m by n matrix A and p by n matrix B from data file

      Read (nin,*)(a(i,1:n),i=1,m)
      Read (nin,*)(b(i,1:n),i=1,p)

!     Compute tola and tolb as
!         tola = max(m,n)*norm(A)*macheps
!         tolb = max(p,n)*norm(B)*macheps

      eps = x02ajf()
      tola = real(max(m,n),kind=nag_wp)*f06uaf('One-norm',m,n,a,lda,rwork)*eps
      tolb = real(max(p,n),kind=nag_wp)*f06uaf('One-norm',p,n,b,ldb,rwork)*eps

!     Compute the factorization of (A, B)
!         (A = U*S*(Q**H), B = V*T*(Q**H))

!     The NAG name equivalent of zggsvp is f08vsf
      Call zggsvp('U','V','Q',m,p,n,a,lda,b,ldb,tola,tolb,k,l,u,ldu,v,ldv,q,   &
        ldq,iwork,rwork,tau,work,info)

!     Print solution

      irank = k + l
      Write (nout,*) 'Numerical rank of (A**T B**T)**T (K+L)'
      Write (nout,99999) irank

      Write (nout,*)
      Flush (nout)
      If (m>=irank) Then

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call x04dbf('Upper','Non-unit',irank,irank,a(1,n-irank+1),lda,         &
          'Bracketed','1P,E12.4','Upper triangular matrix S','Integer',rlabs,  &
          'Integer',clabs,80,0,ifail)

      Else

        ifail = 0
        Call x04dbf('Upper','Non-unit',m,irank,a(1,n-irank+1),lda,'Bracketed', &
          '1P,E12.4','Upper trapezoidal matrix S','Integer',rlabs,'Integer',   &
          clabs,80,0,ifail)

      End If
      Write (nout,*)
      Flush (nout)

      ifail = 0
      Call x04dbf('Upper','Non-unit',l,l,b(1,n-l+1),ldb,'Bracketed',           &
        '1P,E12.4','Upper triangular matrix T','Integer',rlabs,'Integer',      &
        clabs,80,0,ifail)

      Write (nout,*)
      Flush (nout)

      ifail = 0
      Call x04dbf('General',' ',m,m,u,ldu,'Bracketed','1P,E12.4',              &
        'Unitary matrix U','Integer',rlabs,'Integer',clabs,80,0,ifail)

      Write (nout,*)
      Flush (nout)

      ifail = 0
      Call x04dbf('General',' ',p,p,v,ldv,'Bracketed','1P,E12.4',              &
        'Unitary matrix V','Integer',rlabs,'Integer',clabs,80,0,ifail)

      Write (nout,*)
      Flush (nout)

      ifail = 0
      Call x04dbf('General',' ',n,n,q,ldq,'Bracketed','1P,E12.4',              &
        'Unitary matrix Q','Integer',rlabs,'Integer',clabs,80,0,ifail)

99999 Format (1X,I5)
    End Program f08vsfe