Program f07fqfe

!     F07FQF Example Program Text

!     Mark 28.4 Release. NAG Copyright 2022.

!     .. Use Statements ..
      Use nag_library, Only: nag_rp, nag_wp, zcposv
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, info, iter, lda, ldb, ldx, n, r
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: a(:,:), b(:,:), work(:,:), x(:,:)
      Complex (Kind=nag_rp), Allocatable :: swork(:)
      Real (Kind=nag_wp), Allocatable  :: rwork(:)
!     .. Executable Statements ..
      Write (nout,*) 'F07FQF Example Program Results'
      Write (nout,*)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n, r
      lda = n
      ldb = n
      ldx = n
      Allocate (a(lda,n),b(ldb,r),work(n,r),x(ldx,r),swork(n*(n+r)),rwork(n))

!     Read A and B from data file

      Read (nin,*)(a(i,i:n),i=1,n)
      Read (nin,*)(b(i,1:r),i=1,n)

!     Solve the equations Ax = b for x
!     The NAG name equivalent of zcposv is f07fqf
      Call zcposv('U',n,r,a,lda,b,ldb,x,ldx,work,swork,rwork,iter,info)

      If (info==0) Then

!       Print solution

        Write (nout,*) 'Solution'
        Write (nout,99999)(x(i,1:r),i=1,n)

      Else
        Write (nout,99998) 'The leading minor of order ', info,                &
          ' is not positive definite'
      End If

99999 Format ((3X,4(' (',F7.4,',',F7.4,')',:)))
99998 Format (1X,A,I3,A)
    End Program f07fqfe