Program g01safe
!     G01SAF Example Program Text

!     Mark 28.3 Release. NAG Copyright 2022.

!     .. Use Statements ..
      Use nag_library, Only: g01saf, nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, ifail, lout, ltail, lx, lxmu,     &
                                          lxstd
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: p(:), x(:), xmu(:), xstd(:)
      Integer, Allocatable             :: ivalid(:)
      Character (1), Allocatable       :: tail(:)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: max, mod, repeat
!     .. Executable Statements ..
      Write (nout,*) 'G01SAF Example Program Results'
      Write (nout,*)

!     Skip heading in data file
      Read (nin,*)

!     Read in the input vectors
      Read (nin,*) ltail
      Allocate (tail(ltail))
      Read (nin,*) tail(1:ltail)

      Read (nin,*) lx
      Allocate (x(lx))
      Read (nin,*) x(1:lx)

      Read (nin,*) lxmu
      Allocate (xmu(lxmu))
      Read (nin,*) xmu(1:lxmu)

      Read (nin,*) lxstd
      Allocate (xstd(lxstd))
      Read (nin,*) xstd(1:lxstd)

!     Allocate memory for output
      lout = max(ltail,lx,lxmu,lxstd)
      Allocate (p(lout),ivalid(lout))

!     Calculate probability
      ifail = -1
      Call g01saf(ltail,tail,lx,x,lxmu,xmu,lxstd,xstd,p,ivalid,ifail)

      If (ifail==0 .Or. ifail==1) Then
!       Display title
        Write (nout,*)                                                         &
          '   TAIL      X        XMU      XSTD       P     IVALID'
        Write (nout,*) repeat('-',56)

!       Display results
        Do i = 1, lout
          Write (nout,99999) tail(mod(i-1,ltail)+1), x(mod(i-1,lx)+1),         &
            xmu(mod(i-1,lxmu)+1), xstd(mod(i-1,lxstd)+1), p(i), ivalid(i)
        End Do
      End If

99999 Format (5X,A1,3(4X,F6.2),4X,F6.3,4X,I3)
    End Program g01safe