Program f08qlfe

!     F08QLF Example Program Text

!     Mark 28.3 Release. NAG Copyright 2022.

!     .. Use Statements ..
      Use nag_library, Only: dlange => f06raf, dtrevc, dtrsna, nag_wp, x02ajf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: eps, tnorm
      Integer                          :: i, info, ldt, ldvl, ldvr, ldwork, m, &
                                          n
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: s(:), sep(:), t(:,:), vl(:,:),       &
                                          vr(:,:), work(:,:)
      Integer, Allocatable             :: iwork(:)
      Logical                          :: select(1)
!     .. Executable Statements ..
      Write (nout,*) 'F08QLF Example Program Results'
      Write (nout,*)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      ldt = n
      ldvl = n
      ldvr = n
      ldwork = n
      Allocate (s(n),sep(n),t(ldt,n),vl(ldvl,n),vr(ldvr,n),work(ldwork,n+6),   &
        iwork(2*n-1))

!     Read T from data file

      Read (nin,*)(t(i,1:n),i=1,n)

!     Calculate the left and right eigenvectors of T

!     The NAG name equivalent of dtrevc is f08qkf
      Call dtrevc('Both','All',select,n,t,ldt,vl,ldvl,vr,ldvr,n,m,work,info)

!     Estimate condition numbers for all the eigenvalues and right
!     eigenvectors of T

!     The NAG name equivalent of dtrsna is f08qlf
      Call dtrsna('Both','All',select,n,t,ldt,vl,ldvl,vr,ldvr,s,sep,n,m,work,  &
        ldwork,iwork,info)

!     Print condition numbers of eigenvalues and right eigenvectors

      Write (nout,*) 'S'
      Write (nout,99999) s(1:m)
      Write (nout,*)
      Write (nout,*) 'SEP'
      Write (nout,99999) sep(1:m)

!     Calculate approximate error estimates (using the 1-norm)

      eps = x02ajf()
!     f06raf is the NAG name equivalent of the LAPACK auxiliary dlange
      tnorm = dlange('1-norm',n,n,t,ldt,work)
      Write (nout,*)
      Write (nout,*) 'Approximate error estimates for eigenvalues ',           &
        'of T (machine-dependent)'
      Write (nout,99999)(eps*tnorm/s(i),i=1,m)
      Write (nout,*)
      Write (nout,*) 'Approximate error estimates for right ',                 &
        'eigenvectors of T (machine-dependent)'
      Write (nout,99999)(eps*tnorm/sep(i),i=1,m)

99999 Format ((3X,1P,7E11.1))
    End Program f08qlfe