Program f07fe_t1w_fe

!     F07FE_T1W_F Example Program Text
!     Mark 28.3 Release. NAG Copyright 2022.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: f07fd_t1w_f, f07fe_t1w_f,                       &
                               nagad_t1w_set_derivative, nagad_t1w_w_rtype,    &
                               x10aa_t1w_f, x10ab_t1w_f, Assignment (=)
      Use nag_library, Only: nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Integer                          :: i, ifail, lda, ldb, n, nrhs
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Type (nagad_t1w_w_rtype), Allocatable :: a(:,:), ax(:,:), b(:,:), x(:,:)
      Real (Kind=nag_wp), Allocatable  :: ar(:,:), dxdb(:,:), xr(:,:)
!     .. Executable Statements ..
      Write (nout,*) 'F07FE_T1W_F Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n, nrhs
      lda = n
      ldb = n
      Allocate (a(lda,n),b(ldb,nrhs),ax(lda,n),x(ldb,nrhs))
      Allocate (ar(lda,n),xr(ldb,nrhs),dxdb(n,n))

!     Read A and B from data file
      ar = 0.0_nag_wp
      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)(ar(i,i:n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)(ar(i,1:i),i=1,n)
      End If
      a = ar
      Read (nin,*)(xr(i,1:nrhs),i=1,n)
      b = xr

!     Create AD configuration data object
      ifail = 0
      Call x10aa_t1w_f(ad_handle,ifail)

      Do i = 1, n
        Call nagad_t1w_set_derivative(b(i,1),1.0_nag_wp)
        ax = a
        x = b

!       Factorize A
        ifail = 0
        Call f07fd_t1w_f(ad_handle,uplo,n,ax,lda,ifail)

!       Compute solution
        Call f07fe_t1w_f(ad_handle,uplo,n,nrhs,ax,lda,x,ldb,ifail)
        b(i,1)%tangent = 0.0_nag_wp
        dxdb(1:n,i) = x(1:n,1)%tangent
      End Do

!     Print solution
      xr(1:n,1:nrhs) = x(1:n,1:nrhs)%value

      ifail = 0
      Call x04caf('General',' ',n,nrhs,xr,ldb,'Solution(s)',ifail)

      Write (nout,*)
      Write (nout,*) ' Derivatives calculated: First order tangents'
      Write (nout,*) ' Computational mode    : algorithmic'

      Write (nout,*)
      Write (nout,*) ' Derivatives of solution x(:,1) w.r.t. b(:,1)'
      Write (nout,*) ' (i.e. The inverse of A) :'

      Call x04caf('General',' ',n,n,dxdb,n,'',ifail)

!     Remove computational data object
      Call x10ab_t1w_f(ad_handle,ifail)

    End Program f07fe_t1w_fe