Program f01fj_a1w_fe

!     F01FJ_A1W_F Example Program Text

!     Mark 28.3 Release. NAG Copyright 2022.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: f01fj_a1w_f, nagad_a1w_get_derivative,          &
                               nagad_a1w_ir_interpret_adjoint_sparse,          &
                               nagad_a1w_ir_register_variable,                 &
                               nagad_a1w_ir_remove, nagad_a1w_ir_zero_adjoints &
                               , nagad_a1w_set_derivative, nagad_a1w_w_ctype,  &
                               nagad_a1w_w_rtype, x10aa_a1w_f, x10ab_a1w_f,    &
                               x10za_a1w_f, Assignment (=)
      Use nag_library, Only: nag_wp, x04daf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Integer                          :: i, ierr, ifail, j, lda, n
!     .. Local Arrays ..
      Type (nagad_a1w_w_ctype), Allocatable :: a(:,:)
      Type (nagad_a1w_w_rtype), Allocatable :: ai(:,:), ar(:,:)
      Complex (Kind=nag_wp), Allocatable :: a_c(:,:)
!     .. Intrinsic Procedures ..
      Intrinsic                        :: aimag, cmplx, real
!     .. Executable Statements ..
      Write (nout,*) 'F01FJ_A1W_F Example Program Results'
      Write (nout,*)
      Flush (nout)

!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      lda = n
      Allocate (a(lda,n),ar(lda,n),ai(lda,n),a_c(lda,n))

!     Read A from data file
      Read (nin,*)(a_c(i,1:n),i=1,n)

      ar(1:n,1:n) = real(a_c(1:n,1:n))
      ai(1:n,1:n) = aimag(a_c(1:n,1:n))

!     Create AD tape
      Call x10za_a1w_f

!     Create AD configuration data object
      ifail = 0
      Call x10aa_a1w_f(ad_handle,ifail)

!     Register variables to differentiate w.r.t.
      Do i = 1, n
        Call nagad_a1w_ir_register_variable(ar(i,i))
        Do j = 1, n
          a(i,j)%vreal = ar(i,j)
          a(i,j)%vimag = ai(i,j)
        End Do
      End Do

!     ifail: behaviour on error exit
!             =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
      ifail = 0

!     Find log( A )
      Call f01fj_a1w_f(ad_handle,n,a,lda,ifail)

!     Print solution
      a_c = a
      ifail = 0
      Call x04daf('G','N',n,n,a_c,lda,'log(A)',ifail)

      Write (nout,*)
      Write (nout,*) ' Derivatives calculated: First order adjoints'
      Write (nout,*) ' Computational mode    : algorithmic'

      Write (nout,*)
      Write (nout,*) ' Derivatives of diagonal of log(A) w.r.t. diagonal of A'
      Write (nout,*)
!     Setup evaluation of derivatives via adjoints
      Do i = 1, n
        Call nagad_a1w_ir_zero_adjoints
        Call nagad_a1w_set_derivative(a(i,i)%vreal,1.0_nag_wp)
        ifail = 0
        Call nagad_a1w_ir_interpret_adjoint_sparse(ifail)

!       Get derivatives
        Do j = 1, n
          a_c(i,j) = nagad_a1w_get_derivative(ar(j,j))
        End Do

        Call nagad_a1w_ir_zero_adjoints
        Call nagad_a1w_set_derivative(a(i,i)%vimag,1.0_nag_wp)
        ifail = 0
        Call nagad_a1w_ir_interpret_adjoint_sparse(ifail)

!       Get derivatives
        Do j = 1, n
          a_c(i,j) = a_c(i,j) + cmplx(0.0_nag_wp,nagad_a1w_get_derivative(ar(j &
            ,j)),kind=nag_wp)
        End Do
      End Do
      ierr = 0
      Call x04daf('General',' ',n,n,a_c,n,'   d(logA(i,i))/dreal(a(j,j))',     &
        ierr)

!     Remove computational data object and tape
      Call x10ab_a1w_f(ad_handle,ifail)
      Call nagad_a1w_ir_remove

    End Program f01fj_a1w_fe