Program c06rffe

!     C06RFF Example Program Text

!     Mark 28.3 Release. NAG Copyright 2022.

!     .. Use Statements ..
      Use nag_library, Only: c06rff, nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: ieof, ifail, j, m, n, n1
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: x(:,:)
!     .. Executable Statements ..
      Write (nout,*) 'C06RFF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
loop: Do
        Read (nin,*,Iostat=ieof) m, n1
        n = n1 - 1
        If (ieof<0) Then
          Exit loop
        End If

        Allocate (x(n1,m))
        Read (nin,*)(x(1:n1,j),j=1,m)
        Write (nout,*)
        Write (nout,*) 'Original data values'
        Write (nout,*)
        Write (nout,99999)(x(1:n1,j),j=1,m)

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
!       -- Compute transform
        Call c06rff(m,n,x,ifail)

        Write (nout,*)
        Write (nout,*) 'Discrete Fourier cosine transforms'
        Write (nout,*)
        Write (nout,99999)(x(1:n1,j),j=1,m)

!       -- Compute inverse transform
        Call c06rff(m,n,x,ifail)

        Write (nout,*)
        Write (nout,*) 'Original data as restored by inverse transform'
        Write (nout,*)
        Write (nout,99999)(x(1:n1,j),j=1,m)
        Deallocate (x)
      End Do loop

99999 Format (1X,7F10.4)
    End Program c06rffe