Program g01gc_a1w_fe

!     G01GC_A1W_F Example Program Text
!     Mark 27 Release. NAG Copyright 2019.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: g01gc_a1w_f, nagad_a1w_get_derivative,          &
                               nagad_a1w_inc_derivative,                       &
                               nagad_a1w_ir_create => x10za_a1w_f,             &
                               nagad_a1w_ir_interpret_adjoint,                 &
                               nagad_a1w_ir_register_variable,                 &
                               nagad_a1w_ir_remove, nagad_a1w_ir_zero_adjoints &
                               , nagad_a1w_w_rtype, x10aa_a1w_f, x10ab_a1w_f,  &
                               Assignment (=)
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Type (nagad_a1w_w_rtype)         :: df, p, rlamda, tol, x
      Real (Kind=nag_wp)               :: dfr, dpdd, dpdr, dpdx, rr, xr
      Integer                          :: i, ifail, maxit, n
!     .. Local Arrays ..
      Type (nagad_a1w_w_rtype), Allocatable :: dfv(:), rv(:), xv(:)
!     .. Executable Statements ..
      Write (nout,*) 'G01GC_A1W_F Example Program Results'
      Write (nout,*)

!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      Allocate (xv(n),dfv(n),rv(n))

!     Read x values from data file

      Do i = 1, n
        Read (nin,*) xr, dfr, rr
        xv(i) = xr
        dfv(i) = dfr
        rv(i) = rr
      End Do

      Write (nout,99999) 'x', 'df', 'rlamda', 'p', 'p''', 'df''', 'rlamda'''
99999 Format (1X,A5,A8,A10,A6,A11,A11,A11)
      tol = 0.0E0_nag_wp
      maxit = 100

!     Create AD tape
      Call nagad_a1w_ir_create

!     Create AD configuration data object
      ifail = 0
      Call x10aa_a1w_f(ad_handle,ifail)


      Do i = 1, n

        x = xv(i)
        df = dfv(i)
        rlamda = rv(i)
!       Register variables to differentiate w.r.t.
        Call nagad_a1w_ir_register_variable(x)
        Call nagad_a1w_ir_register_variable(df)
        Call nagad_a1w_ir_register_variable(rlamda)

!       Calculate probability
        ifail = -1
        Call g01gc_a1w_f(ad_handle,x,df,rlamda,tol,maxit,p,ifail)

        Call nagad_a1w_ir_zero_adjoints
        Call nagad_a1w_inc_derivative(p,1.0_nag_wp)
        ifail = 0
        Call nagad_a1w_ir_interpret_adjoint(ifail)

!       Get derivatives
        dpdx = nagad_a1w_get_derivative(x)
        dpdd = nagad_a1w_get_derivative(df)
        dpdr = nagad_a1w_get_derivative(rlamda)

        Write (nout,99998) x%value, df%value, rlamda%value, p%value, dpdx,     &
          dpdd, dpdr
      End Do
99998 Format (1X,4(F7.2,1X),1P,3E10.2)

!     Remove computational data object and tape
      Call x10ab_a1w_f(ad_handle,ifail)
      Call nagad_a1w_ir_remove

    End Program g01gc_a1w_fe