Program f07ugfe

!     F07UGF Example Program Text

!     Mark 27.0 Release. NAG Copyright 2019.

!     .. Use Statements ..
      Use nag_library, Only: dtpcon, nag_wp, x02ajf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
      Character (1), Parameter         :: diag = 'N', norm = '1'
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: rcond
      Integer                          :: i, info, j, n
      Character (1)                    :: uplo
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: ap(:), work(:)
      Integer, Allocatable             :: iwork(:)
!     .. Executable Statements ..
      Write (nout,*) 'F07UGF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      Allocate (ap(n*(n+1)/2),work(3*n),iwork(n))

!     Read A from data file

      Read (nin,*) uplo
      If (uplo=='U') Then
        Read (nin,*)((ap(i+j*(j-1)/2),j=i,n),i=1,n)
      Else If (uplo=='L') Then
        Read (nin,*)((ap(i+(2*n-j)*(j-1)/2),j=1,i),i=1,n)
      End If

!     Estimate condition number
!     The NAG name equivalent of dtpcon is f07ugf
      Call dtpcon(norm,uplo,diag,n,ap,rcond,work,iwork,info)

      Write (nout,*)
      If (rcond>=x02ajf()) Then
        Write (nout,99999) 'Estimate of condition number =',                   &
          1.0E0_nag_wp/rcond
      Else
        Write (nout,*) 'A is singular to working precision'
      End If

99999 Format (1X,A,1P,E10.2)
    End Program f07ugfe