Program f07fcfe

!     F07FCF Example Program Text

!     Mark 27.0 Release. NAG Copyright 2019.

!     .. Use Statements ..
      Use nag_library, Only: dsposv, nag_rp, nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Integer                          :: i, info, iter, lda, ldb, ldx, n, r
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: a(:,:), b(:,:), work(:,:), x(:,:)
      Real (Kind=nag_rp), Allocatable  :: swork(:)
!     .. Executable Statements ..
      Write (nout,*) 'F07FCF Example Program Results'
      Write (nout,*)
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n, r
      lda = n
      ldb = n
      ldx = n
      Allocate (a(lda,n),b(n,r),work(n,r),x(ldx,r),swork(n*(n+r)))

!     Read the upper triangular part of A from data file

      Read (nin,*)(a(i,i:n),i=1,n)

!     Read B from data file

      Read (nin,*)(b(i,1:r),i=1,n)

!     Solve the equations Ax = b for x
!     The NAG name equivalent of dsposv is f07fcf
      Call dsposv('U',n,r,a,lda,b,ldb,x,ldx,work,swork,iter,info)

      If (info==0) Then

!       Print solution

        Write (nout,*) 'Solution'
        Write (nout,99999)(x(i,1:r),i=1,n)
      Else
        Write (nout,99998) 'The leading minor of order ', info,                &
          ' is not positive definite'
      End If

99999 Format ((3X,7F11.4))
99998 Format ((1X,A,I3,A))
    End Program f07fcfe