!   F01KBF Example Program Text
!   Mark 27.0 Release. NAG Copyright 2019.

    Module f01kbfe_mod

!     .. Use Statements ..
      Use nag_library, Only: nag_wp
!     .. Implicit None Statement ..
      Implicit None
!     .. Accessibility Statements ..
      Private
      Public                           :: fsin2
    Contains
      Subroutine fsin2(iflag,nz,z,fz,iuser,ruser)

!       .. Scalar Arguments ..
        Integer, Intent (Inout)        :: iflag
        Integer, Intent (In)           :: nz
!       .. Array Arguments ..
        Complex (Kind=nag_wp), Intent (Out) :: fz(nz)
        Complex (Kind=nag_wp), Intent (In) :: z(nz)
        Real (Kind=nag_wp), Intent (Inout) :: ruser(*)
        Integer, Intent (Inout)        :: iuser(*)
!       .. Intrinsic Procedures ..
        Intrinsic                      :: sin
!       .. Executable Statements ..
        Continue
        fz(1:nz) = sin((2.0E0_nag_wp,0.0E0_nag_wp)*z(1:nz))
!       Set iflag nonzero to terminate execution for any reason.
        iflag = 0
        Return
      End Subroutine fsin2
    End Module f01kbfe_mod
    Program f01kbfe

!     F01KBF Example Main Program

!     .. Use Statements ..
      Use f01kbfe_mod, Only: fsin2
      Use nag_library, Only: f01kbf, nag_wp, x02ajf, x04daf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: conda, cond_rel, eps, norma, normfa
      Integer                          :: i, ifail, iflag, lda, n
!     .. Local Arrays ..
      Complex (Kind=nag_wp), Allocatable :: a(:,:)
      Real (Kind=nag_wp)               :: ruser(1)
      Integer                          :: iuser(1)
!     .. Executable Statements ..
      Write (nout,*) 'F01KBF Example Program Results'
      Write (nout,*)
      Flush (nout)

!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n

      lda = n
      Allocate (a(lda,n))

!     Read A from data file
      Read (nin,*)(a(i,1:n),i=1,n)

!     Display A
      ifail = 0
      Call x04daf('G','N',n,n,a,lda,'A',ifail)

!     Find absolute condition number estimate
      ifail = 0
      Call f01kbf(n,a,lda,fsin2,iuser,ruser,iflag,conda,norma,normfa,ifail)

      If (ifail==0) Then
!       Print solution
        Write (nout,*)
        Write (nout,*) 'F(A) = sin(2A)'
        Write (nout,99999) 'Estimated absolute condition number is: ', conda

!       Find relative condition number estimate
        eps = x02ajf()
        If (normfa>eps) Then
          cond_rel = conda*norma/normfa
          Write (nout,99999) 'Estimated relative condition number is: ',       &
            cond_rel
        Else
          Write (nout,99998) 'The estimated norm of f(A) is effectively zero', &
            'and so the relative condition number is undefined.'
        End If

      End If

99999 Format (1X,A,F7.2)
99998 Format (/,1X,A,/,1X,A)
    End Program f01kbfe