Program g02ab_a1t1w_fe

!     G02AB_A1T1W_F Example Program Text
!     Mark 27.3 Release. NAG Copyright 2021.

!     .. Use Statements ..
      Use iso_c_binding, Only: c_ptr
      Use nagad_library, Only: g02ab_a1t1w_f, nagad_a1t1w_get_derivative,      &
                               nagad_a1t1w_inc_derivative,                     &
                               nagad_a1t1w_ir_create => x10za_a1t1w_f,         &
                               nagad_a1t1w_ir_interpret_adjoint,               &
                               nagad_a1t1w_ir_register_variable,               &
                               nagad_a1t1w_ir_remove, nagad_a1t1w_w_rtype,     &
                               nagad_t1w_w_rtype, x10aa_a1t1w_f,               &
                               x10ab_a1t1w_f, Assignment (=)
      Use nag_library, Only: nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Type (c_ptr)                     :: ad_handle
      Type (nagad_a1t1w_w_rtype)       :: alpha, errtol, nrmgrd
      Type (nagad_t1w_w_rtype)         :: t_t
      Real (Kind=nag_wp)               :: dxdg, tmp
      Integer                          :: feval, i, ifail, iter, j, ldg, ldx,  &
                                          lwork, maxit, maxits, n
      Character (1)                    :: opt
!     .. Local Arrays ..
      Type (nagad_a1t1w_w_rtype), Allocatable :: eig(:), g(:,:), g_in(:,:),    &
                                          w(:), work(:), x(:,:)
!     .. Executable Statements ..
      Write (nout,*) 'G02AB_A1T1W_F Example Program Results'
      Write (nout,*)
      Flush (nout)

!     Skip heading in data file
      Read (nin,*)
      alpha = 0.0_nag_wp
!     Read in the problem size, opt and alpha
      Read (nin,*) n, opt, tmp
      alpha = tmp

      ldg = n
      ldx = n
      lwork = 66*n
      Allocate (g(n,n),g_in(n,n),w(n),x(n,n),eig(n),work(lwork))
      x = 0.0_nag_wp

!     Read in the matrix G
      g_in(1:n,1:n) = 0.0_nag_wp
      Read (nin,*)(g_in(i,1:n)%value%value,i=1,n)

!     Read in the vector W
      w(1:n) = 0.0_nag_wp
      Read (nin,*) w(1:n)%value%value

!     Use the defaults for ERRTOL, MAXITS and MAXIT
      errtol = 0.0E0_nag_wp
      maxits = 0
      maxit = 0

      Call nagad_a1t1w_ir_create
      ifail = 0
      Call x10aa_a1t1w_f(ad_handle,ifail)

      g_in(1:n,1:n)%value%tangent = 1.0_nag_wp
      Call nagad_a1t1w_ir_register_variable(g_in(1:n,1:n))
      g(1:n,1:n) = g_in(1:n,1:n)

!     Calculate nearest correlation matrix
      ifail = 0

      Call g02ab_a1t1w_f(ad_handle,g,ldg,n,opt,alpha,w,errtol,maxits,maxit,x,  &
        ldx,iter,feval,nrmgrd,ifail)

!     Display results
      ifail = 0
      Call x04caf('General',' ',n,n,x%value%value,n,                           &
        'Nearest Correlation Matrix X',ifail)
      Write (nout,*)
      Write (nout,99999) 'Number of Newton steps taken:', iter
      Write (nout,99998) 'Number of function evaluations:', feval

      Write (nout,*)
      Write (nout,99997) 'ALPHA: ', alpha%value%value

      Write (nout,*)

      t_t = 1.0_nag_wp
      Call nagad_a1t1w_inc_derivative(x,t_t)

      Call nagad_a1t1w_ir_interpret_adjoint(ifail)

      dxdg = 0.0_nag_wp
      Do i = 1, n
        Do j = 1, n
          t_t = nagad_a1t1w_get_derivative(g_in(i,j))
          dxdg = dxdg + t_t%tangent
        End Do
      End Do

      Call x10ab_a1t1w_f(ad_handle,ifail)
      Call nagad_a1t1w_ir_remove

      Write (nout,*)
      Write (nout,'(1X,A)') 'Sum of Hessian terms for X w.r.t. G'
      Write (nout,*)
      Write (nout,'(1X,A,1P,E12.4)')                                           &
        'Sum_{i,j,k,l,m,n} d^2 X_{m,n} / dG_{i,j} dG_{k,l}: ', dxdg

99999 Format (1X,A,I11)
99998 Format (1X,A,I9)
99997 Format (1X,A,F37.3)

    End Program g02ab_a1t1w_fe