Program f08jgfe

!     F08JGF Example Program Text

!     Mark 27.3 Release. NAG Copyright 2021.

!     .. Use Statements ..
      Use nag_library, Only: blas_damax_val, dpteqr, nag_wp, x04caf
!     .. Implicit None Statement ..
      Implicit None
!     .. Parameters ..
      Real (Kind=nag_wp), Parameter    :: zero = 0.0_nag_wp
      Integer, Parameter               :: nin = 5, nout = 6
!     .. Local Scalars ..
      Real (Kind=nag_wp)               :: r
      Integer                          :: i, ifail, info, k, ldz, n
!     .. Local Arrays ..
      Real (Kind=nag_wp), Allocatable  :: d(:), e(:), work(:), z(:,:)
!     .. Executable Statements ..
      Write (nout,*) 'F08JGF Example Program Results'
!     Skip heading in data file
      Read (nin,*)
      Read (nin,*) n
      ldz = n
      Allocate (d(n),e(n-1),work(4*n),z(ldz,n))

!     Read T from data file

      Read (nin,*) d(1:n)
      Read (nin,*) e(1:n-1)

!     Calculate all the eigenvalues and eigenvectors of T
!     The NAG name equivalent of dpteqr is f08jgf
      Call dpteqr('I',n,d,e,z,ldz,work,info)

      Write (nout,*)
      If (info>0 .And. info<=n) Then
        Write (nout,*) 'T is not positive definite.'
      Else If (info>n) Then
        Write (nout,*) 'Failure to converge.'
      Else

!       Print eigenvalues and eigenvectors

        Write (nout,*) 'Eigenvalues'
        Write (nout,99999) d(1:n)
        Write (nout,*)
        Flush (nout)

!       Normalize the eigenvectors, largest positive
        Do i = 1, n
          Call blas_damax_val(n,z(1,i),1,k,r)
          If (z(k,i)<zero) Then
            z(1:n,i) = -z(1:n,i)
          End If
        End Do

!       ifail: behaviour on error exit
!              =0 for hard exit, =1 for quiet-soft, =-1 for noisy-soft
        ifail = 0
        Call x04caf('General',' ',n,n,z,ldz,'Eigenvectors',ifail)

      End If

99999 Format (3X,(8F8.4))
    End Program f08jgfe